fRO_french_translation_rAthena/npc/jobs/2-1a/WhiteSmith.txt

//===== rAthena Script ======================================= 
//= Advance Class jobchanger after kRO Normals.
//===== By: ==================================================
//= Nana
//= finished, optimized and tested by Lupus
//===== Current Version: ===================================== 
//= 1.3
//===== Compatible With: ===================================== 
//= rAthena Project
//===== Description: ========================================= 
//= Advance Class jobchanger after kRO Normals.
//===== Additional Comments: ================================= 
//= 1.1 Made all into functions, additional checks, etc. [Lupus]
//= 1.2 Made numbers into constants. [Vicious]
//= 1.3 Now saves/restores all the quest skills [Lupus]
//============================================================ 

valkyrie,44,50,5	script	MasterSmith#Valkyrie	731,{
	if (ADVJOB == 0 || Upper != 1) {
		set .@karma_d,rand(1,10);
		if (.@karma_d > 4) {
			mes "[MasterSmith]";
			mes "Congratulations.";
			mes "Honor to the warriors!";
			close;
		}
		mes "[MasterSmith]";
		mes "Ah...";
		mes "The pinnacle";
		mes "of craftsmanship.";
		mes "That's the work of";
		mes "a MasterSmith.";
		next;
		mes "[MasterSmith]";
		mes "Once you're the";
		mes "the best of the best,";
		mes "you begin forging with";
		mes "the goal of discovering";
		mes "new and better ways of";
		mes "crafting...";
		close;
	}
	else if (ADVJOB == Job_WhiteSmith && Class == Job_Merchant_High && JobLevel > 39) {
		mes "[MasterSmith]";
		mes "The time has come!";
		mes "Our world needs brave,";
		mes "hard-working adventurers";
		mes "like you...";
		next;
		mes "[MasterSmith]";
		mes "Would you like to";
		mes "become a MasterSmith?";
		next;
		if (select("No.:Yes.") == 1) {
			mes "[MasterSmith]";
			mes "When you're ready,";
			mes "feel free to come back.";
			mes "Honor to the warriors!";
			close;
		}
		if (SkillPoint) {
			mes "[MasterSmith]";
			mes "It is still possible for you to learn more skills. Please use";
			mes "all of your remaining Skill Points before returning to me.";
			close;
		}
		jobchange Job_Whitesmith;
		set ADVJOB,0;
		mes "[MasterSmith]";
		mes "Congratulations!";
		mes "As a MasterSmith,";
		mes "I hope you will forge";
		mes "a path towards a brighter";
		mes "future for Midgard.";
		close;
	}
	mes "[MasterSmith]";
	mes "Welcome";
	mes "to Valhalla,";
	mes "the Hall of Honor.";
	next;
	mes "[MasterSmith]";
	mes "Please make";
	mes "yourself comfortable";
	mes "while you are here.";
	mes "Honor to the warriors!";
	close;
}