fRO_french_translation_rAthena/npc/cities/alberta.txt

//===== rAthena Script =======================================
//= Ville d'Alberta
//===== By: ==================================================
//= DZeroX
//===== Current Version: =====================================
//= 1.6
//===== Traduction : ============================================
//= OverSu & Liara
//===== Compatible With: =====================================
//= rAthena Project
//===== Description: =========================================
//= PNJ spécifiques à la ville d'Alberta
//===== Commentaires supplémentaires : ==========================
//= 1.0 Converti depuis Aegis 10.4 [DZeroX]
//= 1.1 Optimisé, next manquants corrigés, suppression des .GATs ! [Lupus]
//= 1.2 Correction de progression fournie par $ephiroth. [L0ne_W0lf]
//= 1.2b Nettoyage supplémentaire fourni par Barron-Monster. [L0ne_W0lf]
//= 1.3 Suppression du PNJ "Tourist#al", lié à une quête. [L0ne_W0lf]
//= 1.4 Suppression du doublon "Fastidious Old Man". [L0ne_W0lf]
//= 1.5 Mise à jour pour correspondre au script AEGIS. [Kisuka]
//= 1.6 Ajout des coordonnées RE pour Izlude. [Euphy]
//= 1.7 Corrections de bugs et de syntaxe. [Capuche]
//============================================================

alberta,97,51,0	script	Fabian	84,{
	mes "[Fabian]";
	mes "Quand tu voyages dans le monde entier, t'entends des histoires de fous.";
	next;
	mes "[Fabian]";
	mes "Une fois, on m'a parlé de cartes contenant le pouvoir de monstres. Si quelqu'un met la main dessus, il peut utiliser leur pouvoir.";
	next;
	mes "[Fabian]";
	mes "À mon avis, c’est un effet de mode ou une arnaque. Collectionner toutes les cartes et tout ça… Sérieusement, comment une simple carte pourrait-elle contenir une telle puissance ?";
	next;
	mes "[Fabian]";
	mes "Franchement...";
	close;
}

alberta,53,39,0	script	Steiner	100,{
	mes "[Steiner]";
	mes "Oh... !";
	mes "Bienvenue à Alberta, jeune aventurier !";
	next;
	mes "[Steiner]";
	mes "Excuse-moi si je suis un peu distrait. J’essaie de planifier un petit truc… J’ai entendu dire qu’à Geffen, y’a un magasin qui vend des armures résistantes à la magie.";
	next;
	mes "[Steiner]";
	mes "Si j’en achète un bon paquet, et que je les revends ici plus cher...";
	close;
}

alberta_in,20,183,0	script	Chad	1_M_03,{
	mes "[Chad]";
	mes "On dit que l’arme légendaire Gungnir ne rate jamais sa cible. Tu crois que c’est vrai ?";
	next;
	mes "[Chad]";
	mes "On dit aussi que les cigognes fabriquent les bébés, que les filles aiment les mecs lourds, et que le Père Noël existe ! Mais seulement à Lutie.";
	next;
	mes "[Chad]";
	mes "Je me demande...";
	mes "Si tout ça";
	mes "pouvait être vrai...";
	close;
}

alberta,131,139,2	script	Deagle	1_M_JOBGUIDER,{
	mes "[Deagle]";
	mes "^666666*Hips*^000000";
	mes "Qu-qu'est-ce que tu regardes ? Du vent !!";
	next;
	switch(select("Ne rien dire.","Le laisser tranquille.")) {
	case 1:
		mes "[Deagle]";
		mes "Hahaha ^666666*hips*^000000... T’as du cran. Je n’ai peut-être pas l’air comme ça, mais j’étais marin sur le 'Going Mary'.";
		next;
		switch(select("Jamais entendu parler.","Vraiment ? Sans blague !")) {
		case 1:
			mes "[Deagle]";
			mes "Jamais entendu parler ?! Tout le monde connaît le célèbre navire pirate 'Going Mary' ! ^666666*Hips~*^000000";
			next;
			mes "[Deagle]";
			mes "Ahh... Le bon vieux temps. Si seulement... si seulement on n'avait pas croisé CETTE TEMPÊTE... ^666666*hips*^000000";
			next;
			mes "[Deagle]";
			mes "CAPITAINE ! Il me manque tant... Aucun ennemi ne survivait à sa lame.";
			close;
		case 2:
			mes "[Deagle]";
			mes "C’est exact ! PERSONNE ne cherchait noise à l’équipage du 'Going Mary' ! Et personne ne battait notre capitaine à l’épée !";
			next;
			mes "[Deagle]";
			mes "CAPITAINE~ !!! ^666666*HIPS~*^000000 Il dégainait comme ça, et… ET !!";
			next;
			mes "[Deagle]";
			mes "Son adversaire, et tous ceux à proximité, étaient pris dans les flammes !";
			next;
			mes "[Deagle]";
			mes "Son épée avait un pouvoir mystérieux, ou alors il était juste trop balèze...";
			next;
			mes "[Deagle]";
			mes "Pfiou~~ ^666666*Snif* *Snif...*^000000 Bon sang, tout ça me manque ! Allez, fiche-moi le camp.";
			close;
		}
	case 2:
		mes "[Deagle]";
		mes "Ouais, c’est ça !";
		mes "Dégage~";
		close;
	}
}

alberta,58,80,2	script	Shakir	99,{
	mes "[Shakir]";
	if (rand(2)) {
		mes "Les Marchands ont des talents de négociation uniques. On peut vendre nos objets à un prix bien meilleur.";
		next;
		mes "[Shakir]";
		mes "C’est pas juste crier 'Donne-moi plus !'. Faut du charisme, et maîtriser la rhétorique.";
		next;
		mes "[Shakir]";
		mes "On peut obtenir jusqu’à 24% de zeny en plus grâce à cette compétence. Mais il faut s’entraîner dur pour l’apprendre !";
	} else {
		mes "Nous, Marchands, on peut";
		mes "installer des échoppes ambulantes.";
		next;
		mes "[Shakir]";
		mes "Grâce à la compétence de Réduction, on achète moins cher dans les magasins, on remplit notre chariot...";
		next;
		mes "[Shakir]";
		mes "...et ensuite, on voyage pour vendre ailleurs et faire du profit !";
		next;
		mes "[Shakir]";
		mes "C’est plus pratique et sécurisé comme ça. Essaie de pas t’endormir pendant, même si c’est facile.";
	}
	close;
}

alberta,62,156,2	script	Sonya	102,{
	mes "[Sonya]";
	switch(rand(3)){
	case 0:
		mes "Tu sais, une fois, je marchais en forêt et j’ai vu une tige verte qui bougeait.";
		next;
		mes "[Sonya]";
		mes "Je me suis approchée et j’ai voulu la toucher… et elle m’a mis une claque !";
		next;
		mes "[Sonya]";
		mes "J’ai reculé d’un bond, et là, j’ai réalisé que ce n’était pas une tige... mais un tout petit animal.";
		next;
		mes "[Sonya]";
		mes "Heureusement que je ne l’ai pas énervé. Même les plus petits peuvent être dangereux.";
		close;
	case 1:
		mes "Tu vois ces ours paresseux qu’on croise en allant vers Payon ?";
		next;
		mes "[Sonya]";
		mes "Par curiosité, j’ai lancé un caillou… et là il m’a chargée ! J’ai eu la peur de ma vie, j’ai pris la fuite et BAM !!";
		next;
		mes "[Sonya]";
		mes "Il s’est mangé une branche basse et s’est assommé ! Je ne ferai plus jamais ça pour rigoler.";
		close;
	case 2:
		mes "J’ai vu une meute de loups affronter un de ces énormes ours paresseux !";
		next;
		mes "[Sonya]";
		mes "Les loups sont plus solidaires qu’on ne le pense. Si l’un d’eux est attaqué, les autres accourent.";
		next;
		mes "[Sonya]";
		mes "Réfléchis à deux fois avant d’en affronter un quand ses potes sont dans les parages.";
		close;
	}
}

alberta,93,174,2	script	Grand-mère Alma	103,{
	mes "[Grand-mère Alma]";
	mes "Il y a quelque temps,";
	mes "un vieux navire à l’abandon";
	mes "s’est échoué dans le port d’Alberta.";
	next;
	mes "[Grand-mère Alma]";
	mes "Certains habitants ont tenté d’y entrer pour sauver d’éventuels survivants. Mais ils sont tous ressortis en panique, disant que des cadavres marchaient à l’intérieur.";
	next;
	mes "[Grand-mère Alma]";
	mes "Le bateau grouillait aussi de créatures marines dangereuses, et personne ne voulait y remettre les pieds.";
	next;
	mes "[Grand-mère Alma]";
	mes "On n’a rien pu faire, et on l’a laissé là. Maintenant, des équipes d’exploration tentent d’entrer pour éliminer les monstres.";
	next;
	mes "[Grand-mère Alma]";
	mes "Ce serait une bonne expérience pour un jeune comme toi... mais ne mets pas ta vie en danger si tu n’es pas prêt.";
	close;
}

alberta,189,151,5	script	Fisk	4W_SAILOR,{
	mes "[Fisk]";
	mes "Ohé matelot,";
	mes "tu veux aller où ?";
	next;
	switch(select("Épave engloutie -> 250 zeny.","Port d'Izlude -> 500 zeny.","Euh... finalement non.")) {
	case 1:
		if (Zeny < 250) {
			mes "[Fisk]";
			mes "Hé là ! Pas d’arnaque, j’ai dit 250 zeny !";
			close;
		}
		Zeny -= 250;
		warp "alb2trea",43,53;
		end;
	case 2:
		if (Zeny < 500) {
			mes "[Fisk]";
			mes "Pas de zeny, pas de voyage. C’est pas une croisière gratuite ici !";
			close;
		}
		Zeny -= 500;
		if (checkre(0))
			warp "izlude",195,212;
		else
			warp "izlude",176,182;
		end;
	case 3:
		mes "[Fisk]";
		mes "Bon ben...";
		mes "T'es qu'un terrien, va.";
		close;
	}
}

alb2trea,39,50,6	script	Fisk#a2t	4W_SAILOR,{
	mes "[Fisk]";
	mes "Tu veux rentrer à Alberta, hein ?";
	next;
	if (select("Oui, s’il vous plaît.","En fait, non.") == 1)
		warp "alberta",192,169;
	close;
}

alberta,195,151,2	script	Paul	4_M_04,{
	mes "[Paul]";
	mes "Bonjour~";
	mes "Tu veux rejoindre";
	mes "l’équipe d’exploration";
	mes "du Navire Englouti ?";
	next;
	mes "[Paul]";
	mes "Oh ! Avant de t’engager, sache que si t’es pas assez costaud, tu risques de le regretter.";
	next;
	mes "[Paul]";
	mes "Alors, tenté ?";
	mes "L’entrée ne coûte que";
	mes "200 zeny.";
	next;
	switch(select("J’m’inscris !","Euh, non merci.")) {
	case 1:
		if (Zeny < 200) {
			mes "[Paul]";
			mes "T’as pas les sous, mon ami. Reviens quand tu pourras payer.";
			close;
		}
		Zeny -= 200;
		warp "alb2trea",62,69;
		close;
	case 2:
		mes "[Paul]";
		mes "Pas de souci...";
		mes "Je suis là si tu changes d’avis.";
		close;
	}
}

alberta,190,173,4	script	Phelix	4_M_03,{
	mes "[Phelix]";
	if ((MaxWeight - Weight) < 10000) {
		mes "Hop hop hop !!";
		mes "T’es déjà chargé comme une mule !";
		mes "Tu peux pas porter plus d’objets.";
		mes "Allège un peu, puis reviens.";
		close;
	}
	if (@event_zelopy == 0) {
		mes "Qu'est-ce que tu fiches là ?";
		mes "Ici, rien n’est gratuit. Tu veux un truc ? Taffe pour !";
		next;
		mes "[Phelix]";
		mes "Tiens, ramène-moi 10 Jellopies et je te file une potion rouge. Sinon, 3 Jellopies pour une carotte, pour les plus fragiles.";
		next;
		mes "[Phelix]";
		mes "Si ça te branche, ramène-moi ce que j’ai dit.";
		@event_zelopy = 1;
		close;
	}
	mes "Alors, tu veux échanger tes Jellopies pour des Potions ou des Carottes ?";
	next;
	switch(select("Des Potions rouges !","Des Carottes !")) {
	case 1:
		mes "[Phelix]";
		mes "Voyons voir...";
		next;
		mes "[Phelix]";
		if (countitem(909) < 10) {
			mes "Hé ! T’as écouté ou pas ? 10 Jellopies pour UNE potion. T’es sourd ?";
			close;
		} else {
			.@max = countitem(909)/10;
			mes "Pas mal...";
			mes "Combien tu veux de potions ?";
			next;
			switch(select("Autant que possible.","Je veux choisir.","Finalement, j’aime mes Jellopies.")) {
			case 1:
				delitem 909, .@max * 10;
				getitem 501, .@max;
				break;
			case 2:
				mes "[Phelix]";
				mes "Pas plus de 100 à la fois, compris ? Si t’en veux pas, tape 0.";
				mes "Tu peux en avoir " + .@max + " max. Pas plus. Je vais pas me casser le dos.";
				input .@amount;
				next;
				mes "[Phelix]";
				if (.@amount <= 0) {
					mes "Bien. Reviens quand tu veux.";
					close;
				}
				if (.@amount > 100) {
					mes "J’ai dit MAXIMUM 100 ! T’essaies de m’achever ou quoi ?";
					close;
				}
				if (countitem(909) < .@amount * 10) {
					mes "Pas assez de Jellopies, mon pote. Va farmer un peu.";
					close;
				}
				delitem 909, .@amount * 10;
				getitem 501, .@amount;
				break;
			case 3:
				mes "[Phelix]";
				mes "Très bien. À la prochaine.";
				close;
			}
			mes "[Phelix]";
			mes "Et voilà ! Comme promis. Évite de tout boire d’un coup, hein.";
			close;
		}
	case 2:
		mes "[Phelix]";
		mes "Voyons ce que t’as là...";
		next;
		mes "[Phelix]";
		if (countitem(909) < 3) {
			mes "T’as pas écouté ou quoi ? 3 Jellopies pour UNE carotte.";
			close;
		}
		.@max = countitem(909)/3;
		mes "Pas mal, mauviette...";
		mes "Combien tu veux de carottes ?";
		next;
		switch(select("Autant que possible.","Je veux choisir.","Finalement, j’aime mes Jellopies.")) {
		case 1:
			delitem 909, .@max * 3;
			getitem 515, .@max;
			break;
		case 2:
			mes "[Phelix]";
			mes "Encore une fois : pas plus de 100. Sinon, tu rêves.";
			input .@amount;
			next;
			mes "[Phelix]";
			if (.@amount == 0) {
				mes "Très bien. À plus tard.";
				close;
			}
			if (.@amount > 100) {
				mes "Oh le fragile... J’ai dit 100 max ! Tu veux me tuer ou quoi ?";
				close;
			}
			if (countitem(909) < .@amount * 3) {
				mes "T’en as pas assez. Va en chercher d'autres si tu veux une carotte.";
				close;
			}
			delitem 909, .@amount * 3;
			getitem 515, .@amount;
			break;
		case 3:
			mes "[Phelix]";
			mes "Allez, à la revoyure.";
			close;
		}
		mes "[Phelix]";
		mes "Et voilà~ Comme prévu. Essaie pas de t’étouffer.";
		close;
	}
}