fRO_french_translation_rAthena/npc/cities/brasilis.txt

//===== OverSu & Liara Script ================================== 
//= Ville de Brasilis
//===== Description : ==========================================
//= [Conversion Officielle]
//= Script de la ville de Brasilis
//===== Journal des modifications : ============================
//= 1.0 Première version. Transport et PNJ de base. [L0ne_W0lf]
//= 1.1 Correction du retrait de zeny non effectué. [Kisuka]
//= 1.2 Dialogues mis à jour, ajout de la vendeuse de glaces. [L0ne_W0lf]
//= 1.3 PNJ d’Alberta déplacé vers les chemins pre-re/re. [Euphy]
//= 1.4 Ajout des fonctionnalités VIP. [Euphy]
//==============================================================

// Transport pour Brasilis :: brasilis_trans
//==============================================================
-	script	::Crewman_bra2	-1,{
	mes "[Membre d'équipage]";
	mes "Hé, tu as entendu parler d’un endroit appelé Brasilis ?";
	mes "C’est une ville tropicale, chaude comme le désert mais avec des pluies fréquentes. Un endroit très mystérieux.";
	next;
	mes "[Membre d'équipage]";
	mes "On a récemment découvert une nouvelle route maritime pour s’y rendre facilement.";
	if (VIP_SCRIPT) {
		set .@cost, vip_status(VIP_STATUS_ACTIVE)?1000:10000;
		mes "Le trajet aller-retour coûte seulement 10 000 zeny, ou 1 000 si tu es VIP ! Tu veux y aller ?";
	} else {
		set .@cost,10000;
		mes "Le trajet aller-retour ne coûte que 10 000 zeny ! Tu veux embarquer ?";
	}
	next;
	switch(select("Emmène-moi à Brasilis !:Je reste ici.")) {
	case 1:
		if (Zeny < .@cost) {
			mes "[Membre d'équipage]";
			mes "J'ai dit "+callfunc("F_InsertComma",.@cost)+" zeny.";
			close;
		}
		else {
			mes "[Membre d'équipage]";
			mes "Parfait~!! En route~!";
			set Zeny, Zeny-.@cost;
			close2;
			warp "brasilis",314,60;
			end;
		}
	case 2:
		mes "[Membre d'équipage]";
		mes "Si jamais tu changes d’avis, fais-moi signe et je t’y emmènerai.";
		close;
	}
}

brasilis,316,57,3	script	Crewman#bra1	100,{
	mes "[Membre d'équipage]";
	mes "Mon navire retourne à Alberta, tu veux venir avec nous ?";
	next;
	switch(select("Retourner à Alberta.:Pas tout de suite~.")) {
	case 1:
		mes "[Membre d'équipage]";
		mes "La maison me manque...";
		close2;
		if (checkre(0))
			warp "alberta",245,87;
		else
			warp "alberta",244,115;
		end;
	case 2:
		mes "[Membre d'équipage]";
		mes "Très bien, à plus tard alors.";
		close;
	}
}

// PNJ génériques de Brasilis :: brazil_tre
//============================================================
brasilis,155,165,3	script	Signpost#bra1	858,{
	mes ":: Musée d’art ::";
	close;
}

brasilis,191,239,3	script	Signpost#bra2	858,{
	mes ":: Monument Verass ::";
	close;
}

brasilis,240,247,3	script	Signpost#bra3	858,{
	mes ":: Marché ::";
	mes " ";
	mes "- Pour toutes vos potions et armes -";
	close;
}

brasilis,303,309,3	script	Signpost#bra4	858,{
	mes ":: Téléphérique de la jungle ::";
	mes "- Âmes sensibles s’abstenir -";
	close;
}

brasilis,278,137,3	script	Signpost#bra5	858,{
	mes ":: Hôtel de Brasilis ::";
	close;
}

brasilis,137,77,5	script	Ice-Cream Maker	85,{
	mes "[Marchand de Glaces]";
	mes "Approchez~ approchez~";
	mes "Une bonne glace, c’est parfait quand il fait chaud~";
	mes "C’est seulement ^3355FF100 Zeny^000000~";
	mes "Glace~";
	mes "Prenez votre glace !";
	next;
	switch(select("J’en veux une !:Une glace ?:Annuler.")) {
	case 1:
		mes "[Marchand de Glaces]";
		mes "Comme beaucoup veulent une glace, je limite à 5 par personne.";
		mes "Alors, combien en veux-tu ?";
		next;
		while(1) {
			input .@input;
			if (.@input == 0) {
				mes "[Marchand de Glaces]";
				mes "Rien ?";
				mes "Allez, dégage de là, j’ai d’autres clients.";
				close;
			}
			else if ((.@input < 0) || (.@input > 5)) {
				mes "[Marchand de Glaces]";
				mes "Wow.";
				mes "Tu veux trop en acheter.";
				mes "Si tu en manges plus de 5, tu risques de combattre un monstre... dans ton estomac.";
				next;
			}
			else
				break;
		}
		set .@icecream_hap,.@input*100;
		if (Zeny < .@icecream_hap) {
			mes "[Marchand de Glaces]";
			mes "Eh ben ! T’as pas assez de zeny.";
			mes "C’est juste ^3355FF100 Zeny^000000~ Franchement !";
			close;
		}
		if (!checkweight(536,.@input)) {
			mes "[Marchand de Glaces]";
			mes "Tu transportes trop de trucs.";
			mes "Allège-toi un peu avant d’en acheter.";
			close;
		}
		set Zeny, Zeny-.@icecream_hap;
		getitem 536,.@input; //Glace
		close;
	case 2:
		mes "[Marchand de Glaces]";
		mes "'Une glace, c’est...'";
		mes "Attends, tu sais même pas";
		mes "ce que c’est une glace ?";
		mes "Tu vivais sous un rocher ?";
		next;
		mes "[Marchand de Glaces]";
		mes "J’vais même pas commencer à expliquer à quel point c’est bizarre.";
		mes "Bref, prends ta glace tant qu’elle est bien froide.";
		close;
	case 3:
		mes "[Marchand de Glaces]";
		mes "Ne rate pas l’occasion de goûter la meilleure glace du continent~ !";
		close;
	}
}