fRO_french_translation_rAthena/npc/airports/yuno.txt

//===== rAthena Script ======================================= 
//= Yuno Airport Staff
//===== By: ================================================== 
//= L0ne_W0lf, Muad_Dib
//===== Current Version: =====================================
//= 1.0
//===== Compatible With: ===================================== 
//= rAthena Project
//===== Description: ========================================= 
//= Yuno Airport Staff
//===== Additional Comments: ================================= 
//= 1.0 First version.
//============================================================ 

y_airport,143,43,5	script	Airport Staff#y_air1a::y_airport1	90,{
	mes "[Airport Staff]";
	mes "Welcome to Juno Airport where we offer domestic flights to Einbroch, Lighthalzen and Hugel,";
	mes "and international flights to Izlude and Rachel.";
	mes "How may I be of service?";
	next;
	if (select("Board the Airship.:Cancel.") == 1) {
		mes "[Airport Staff]";
		mes "The boarding fee for all";
		mes "flights is 1,200 zeny. If you";
		mes "use a Free Ticket for Airship,";
		mes "the boarding fee will be waived.So would you like to depart?";
		next;
		if (select("Yes:No") == 1) {
			if (countitem(7311) > 0) {
				delitem 7311,1; //Free_Flying_Ship_Ticket
				warp "y_airport",148,51;
				end;
			}
			if (Zeny >= 1200) {
				set Zeny, Zeny - 1200;
				warp "y_airport",148,51;
				end;
			}
			mes "[Airport Staff]";
			mes "I'm sorry, but you don't";
			mes "have 1,200 zeny to pay";
			mes "for the boarding fee.";
			close;
		}
	}
	mes "[Airport Staff]";
	mes "Thank you and";
	mes "have a nice day.";
	close;
}

y_airport,158,43,5	duplicate(y_airport1)	Airport Staff#y_air1b	90
y_airport,126,43,5	duplicate(y_airport1)	Airport Staff#y_air1c	90

y_airport,143,49,3	script	Arrival Staff#y_air2a::y_airport2	90,{
	mes "[Airport Staff]";
	mes "Welcome to Juno Airport. If you've just arrived from your";
	mes "flight, let me guide you to the main terminal. Otherwise, please";
	mes "board the departing Airship to reach your intended destination.";
	next;
	if (select("Exit to main terminal:Cancel") == 1) {
		mes "[Airport Staff]";
		mes "Once you're in the main terminal, you must pay the fee once again";
		mes "to board a departing Airship. You should only exit if your intended";
		mes "destination is Juno. Proceed to";
		mes "exit to the main terminal?";
		next;
		if (select("Yes:No") == 1) {
			warp "y_airport",142,40;
			end;
		}
	}
	mes "[Airport Staff]";
	mes "Alright, thank you";
	mes "for your patronage";
	mes "and I hope you have";
	mes "a pleasant flight~";
	close;
}

y_airport,126,51,3	duplicate(y_airport2)	Arrival Staff#y_air2b	90
y_airport,158,50,3	duplicate(y_airport2)	Arrival Staff#y_air2c	90

y_airport,145,63,5	script	Domestic Boarding	91,{
	mes "[Boarding Staff]";
	mes "Would you like to board the";
	mes "Airship that flies to Einbroch,";
	mes "Lighthalzen and Hugel? If so,";
	mes "please let me guide you to that";
	mes "Airship's boarding area.";
	next;
	if (select("Yes:No") == 1) {
		warp "yuno",59,244;
		end;
	}
	mes "[Boarding Staff]";
	mes "Very well, then.";
	mes "Thank you for your";
	mes "patronage, and I hope";
	mes "you enjoy your travels~";
	close;
}

y_airport,140,63,5	script	International Boarding	91,{
	mes "[Boarding Staff]";
	mes "Would you like to board";
	mes "the Airship which flies to";
	mes "Juno, Izlude and Rachel?";
	mes "If so, let me guide";
	mes "you to the boarding area.";
	next;
	if (select("Yes:No") == 1) {
		warp "yuno",47,244;
		end;
	}
	mes "[Boarding Staff]";
	mes "Alright, then.";
	mes "Thank you for flying";
	mes "with us, and I hope you";
	mes "enjoy your travels on our";
	mes "state of the art Airships.";
	close;
}

yuno,14,262,5	script	Airship Staff#yuno01	91,{
	mes "[Airship Staff]";
	mes "Welcome to Juno Airport.";
	mes "Please use this door to";
	mes "board the Airship that will";
	mes "be flying all the way to Izlude";
	mes "in the Rune-Midgarts Kingdom,";
	mes "and to Rachel in the Arunafeltz";
	mes "Republic.";
	next;
	mes "[Airship Staff]";
	mes "Otherwise, if Juno is";
	mes "your intended destination,";
	mes "please head down the stairs";
	mes "and ask the Arrival Staff to lead";
	mes "you to the main terminal. Thank";
	mes "you, and enjoy your travels.";
	close;
}

yuno,88,263,3	script	Airship Staff#yuno02	91,{
	mes "[Airship Staff]";
	mes "Welcome to Juno Airport.";
	mes "Please use this door to";
	mes "board the Airship which stops";
	mes "over Einbroch, Lighthalzen and";
	mes "Hugel in the Schwaltzvalt Republic.";
	next;
	mes "[Airship Staff]";
	mes "Otherwise, if Juno is";
	mes "your intended destination,";
	mes "please head down the stairs";
	mes "and ask the Arrival Staff to lead";
	mes "you to the main terminal. Thank";
	mes "you, and enjoy your travels.";
	close;
}