fRO_french_translation_rAthena/npc/quests/newgears/new_hats_0625.txt

//===== eAthena Script ============
//= New hats from kRO Sakray on 2005-05-31
//===== By: =========================
//= Lorky, Lupus
//===== Current Version: ===================
//= 0.7
//===== Compatible With: =====================
//= eAthena 1.0
//===== Description: ============================================
//Hats lists:
//	Crunch Toast
//	Renown Detective's Cap
//	Red Bonnet
//	Baby Pacifier
//	Crunch Toast
//	Winter Hat
//	Zherlthsh Mask
//===== Additional Comments: ==========================================
// 03.06.2005	:: Lorky ::	First release 0.1a
// 0.1b Fixed some missing things with temp IDs. [Lupus]
// 		Could someone correct wrong info, names, coords, etc? ^___-
// 0.1c Fixed hats shop. It shouldn't sell slotted hats.
// 0.2 Fixed Detective Hat items (by Ishizu-chan) [Lupus]
// 0.3 Added Zealotus mask quest with correct items [Lupus]
// 0.4 Fixed some sprites, npc names and coords [Lupus]
// 0.5 Removed temp shops, Black Clothes -> Piece of Black Quartz, thx to vicious_Pucca for note [Lupus]
// 0.5a Updated detective hat to ask for the correct items [Kayla]
// 0.6 Fixed possible exploits. Update yuor servers! [Lupus]
// 0.7 Changed item names to the new official ones, and fixed some Engrish [Poki#3]
//=====================================================================

//Links (some info related to these headgears)
//http://translate.google.com/translate?hl=en&sl=ja&u=http://www11.big.or.jp/~top/2005/0625/head.htm
//http://eathena.deltaanime.net/board/index.php?showtopic=34214
//http://www.ragnainfo.net/forums/viewtopic.php?t=79677&start=0&postdays=0&postorder=asc&highlight=


//-------------------------------------------------------------------------------------------------
// Crunch Toast (ID 5107)
yuno.gat,224,116,4	script	Kacis	818,{
	mes "[Kacis]";
	mes "Do you want a ^FF3300Crunch Toast^000000?";
	next;
	menu "Please, make one for me",-,"No, thanks. I'm so full",L_EXIT;

	if(countitem(519) < 50 || countitem(548) < 50 || countitem(539) < 50 || countitem(7031)<50) goto L_NOITEM;//Items: Milk, Cheese, Piece_of_Cake, Old_Frying_Pan,
	delitem 519,50;	// Milk
	delitem 548,50;	// Cheese
	delitem 539,50;	// Piece of Cake
	delitem 7031,50;	// Old Frying Pan
	mes "[Kacis]";
	mes "Good, thank you! Let me just take your items.";
	next;
	mes "[Kacis]";	
	mes "Well done. Be careful, it's hot.";
	getitem 5107,1;	// Crunch Toast
	close;

L_NOITEM:
	mes "[Kacis]";
	mes "Well, for me to make you a ^FF3300Crunch Toast^000000";
	mes "I'll require these materials:";
	mes "^FF3300 50 Milk, ^000000";
	mes "^FF3300 50 Cheese, ^000000";
	mes "^FF3300 50 Piece of Cake, ^000000";
	mes "^FF3300 50 Old Frying Pan. ^000000";
	close;
L_EXIT:
	mes "[Kacis]";
	mes "I want more tasty toasts!";
	close;
}


//-------------------------------------------------------------------------------------------------
// Renown Detective's Cap (ID 5108)
lighthalzen.gat,140,68,4	script	Morris	818,{
	mes "[Morris]";
	mes "Do you want a ^FF3300Renown Detective's Cap^000000?"; 
	next;
	menu "Of course, I do",-,"No, thanks",L_EXIT;

	mes "[Morris]";
	mes "Very well. Now I can make it...";
	if(countitem(611)<10 || countitem(7301)<1887 || countitem(5120)<1 || Zeny<50000) goto L_NOITEM;//Items: Magnifier, Tassel, Wide_Bunker_Hat_,
	delitem 611,10;	// Magnifier
	delitem 7301,1887;	// Tassel
	delitem 5120,1;	// Bucket Hat [1]
	set Zeny,Zeny-50000;
	next;
	mes "[Morris]";
	mes "Enjoy.";
	getitem 5108,1;	// Renown Detective's Cap
	close;

L_NOITEM:
	mes "[Morris]";
	mes "Bring me:";
	mes "^FF3300 10 Magnifier^000000,";
	mes "^FF3300 1887 Tassel^000000,";
	mes "^FF3300 1 Bucket Hat [1]^000000,";
	mes "and ^FF3300 50,000 zeny.^000000";
	close;

L_EXIT:
	mes "[Morris]";
	mes "Bye.";
	close;
}


//-------------------------------------------------------------------------------------------------
// Red Bonnet (ID 5109)
lighthalzen.gat,180,88,4	script	Rich Girl	818,{
	mes "[Rich Girl]";
	mes "Hello there! Please, answer my questions...";
	next;
	mes "[Rich Girl]";
	mes "Do you have a grandma?";
	emotion e_hmm;
	next;
	mes "[Rich Girl]";
	mes "Really? I'm sorry. Do you like wolves?";
	next;
	mes "[Rich Girl]";
	mes "Ha! I knew it! And... my last question. Would you like to put on something reddish?";
	emotion e_what;
	next;
	mes "[Rich Girl]";
	mes "Just kidding, Have you ever read 'Red-Hood'? I can make to you the very same ^FF3300Red Bonnet^000000.";
	next;
	menu "Please, make it!",-,"No, thanks",L_EXIT;
	if(countitem(10015) < 1 || countitem(975) < 1 || countitem(10007) < 1 || countitem(5032)<1 || Zeny<50000) goto L_NOITEM;//Items: Green_Lace, Scarlet_Dyestuffs, Silk_Ribbon, Sunday_Hat,
	delitem 10015,1;	// Green Lace
	delitem 975,1;	// Scarlet Dyestuff
	delitem 10007,1;	// Silk Ribbon
	delitem 5032,1;	// Sunday Hat
	set Zeny,Zeny-50000;
	mes "[Rich Girl]";
	mes "Ok then, I shall make one for you.";
	next;
	mes "[Rich Girl]";
	mes "Now you can drink tea with your grannie and have fun with wolves.";
	getitem 5109,1;	//Items: Red_Bonnet,
	close;

L_NOITEM:
	mes "[Rich Girl]";
	mes "Give me:";
	mes "^FF3300 Green Lace^000000,";
	mes "^FF3300 Scarlet Dyestuff^000000,";
	mes "^FF3300 Silk Ribbon^000000,";
	mes "^FF3300 Sunday Hat^000000,";
	mes "and ^FF3300 50,000 zeny.^000000";
	close;

L_EXIT:
	mes "[Rich Girl]";
	mes "Well done. Bye.";
	close;
}


//-------------------------------------------------------------------------------------------------
// Baby Pacifier (ID 5110)
lighthalzen.gat,360,310,4	script	Boy	818,{  
	mes "[Boy]";
	mes "...MA...Ma..ma...";
	emotion e_slur;
	next;
	menu "Wow! Give me a Baby Pacifier!",-,"Nice Boy!",L_EXIT;

	mes "[Boy]";
	mes "Rrr..Rrr.. (^FF3300Royal Jelly^000000)";
	mes "Bu.. Ba...Ba-Bu-bi (^FF3300Nursing Bottle^000000)";
	mes "Pa-Pa..Paxfi.. (^FF3300Pacifier^000000)";
	mes "Nu..Noos rie.. (^FF3300Nose Ring^000000)";
	next;

	if(countitem(526)<1 || countitem(7270)<1 || countitem(10004)<1 || countitem(941)<1) goto L_EXIT;//Items: Royal_Jelly, Baby_Bottle, Pacifier, Nose_Ring,
	delitem 526,1;	// Royal Jelly
	delitem 7270,1;	// Nursing Bottle
	delitem 10004,1;	// Pacifier
	delitem 941,1;	// Nose Ring
	mes "[Boy]";
	mes "Th-anke...";
	emotion e_slur;
	getitem 5110,1;	// Baby Pacifier
	next;

L_EXIT:
	mes "[Boy]";
	mes "...B...Bye...";
	emotion e_sob;
	close;
	
}


//-------------------------------------------------------------------------------------------------
// Winter Hat (ID 5115)
einbech.gat,70,200,7	script	Mater	818,{
	mes "[Mater]";
	mes "Aren't you cold?";
	mes "I can make you a ^FF3300Winter Hat^000000";
	next;
	menu "Please, make one for me",-,"No, thanks",L_EXIT;

	if(countitem(7267) < 999 || countitem(983) < 1 || countitem(749) < 1 || Zeny<50000) goto L_NOITEM;//Items: Tigerskin_Underwear, Black_Dyestuff, Frozen_Rose,
	delitem 7267,999;	// Tiger Panty
	delitem 983,1;	// Black Dyestuff
	delitem 749,1;	// Frozen Rose
	set Zeny,Zeny-50000;
	mes "[Mater]";
	mes "Exellent! Now give me the items.";
	next;
	mes "[Mater]";
	mes "Here you are.";
	getitem 5115,1;	// Winter Hat
	close;
L_NOITEM:
	mes "[Mater]";
	mes "Please, correct these materials:";	
	mes "^FF3300 999 Tiger Panty^000000,";
	mes "^FF3300 Black Dyestuff^000000,";
	mes "^FF3300 Frozen Rose^000000,";
	mes "and ^FF3300 50,000 zeny.^000000";
	close;
L_EXIT:
	mes "[Mater]";
	mes "Azzz youu wishhhh... Brr-r.";
	close;
}


//-------------------------------------------------------------------------------------------------
// Mystic rose (ID 5117)
lhz_in02.gat,103,31,4	script	Margaret Mary	818,{
	mes "[Margaret Mary]";
	mes "Wheee! Don't you just love making youself look pretty!?";
	mes "I love glamourising myself with all the best accessories!";
	next;

	mes "[Margaret Mary]";
	mes "Have you ever heard of a ^FF3300Mystic Rose^000000?";
	mes "I can make you one, and you could be fashionable and mysticly, too!";
	next;
	menu "Make me a ^670000Mystic rose^000000.",-,"No, I dont want one.",L_EXIT;
	
	if(countitem(731) < 10 || countitem(748) < 3 || countitem(982) < 1 || Zeny<50000) goto L_NOITEM;//Items: 2_Carat_Diamond, Witherless_Rose, White_Dyestuff,
	delitem 731,10;	// 2carat Diamond
	delitem 748,3;	// Witherless Rose
	delitem 982,1;	// White Dyestuff
	set Zeny,Zeny-50000;
	mes "[Margaret Mary]";
	mes "Wow, thank you! Hand me your items, please.";
	next;
	mes "[Margaret Mary]";
	mes "Enjoy being pretty and mystic!";
	getitem 5117,1;	// Mystic Rose
	close;
L_NOITEM:
	mes "[Margaret Mary]";
	mes "Well, for me to make you my Mystic rose...";
	mes "I need these materials:";
	mes "^FF3300 10 2carat Diamond^000000,";
	mes "^FF3300 3 Witherless Rose^000000,";
	mes "^FF3300 1 White Dyestuff^000000,";
	mes "and ^FF3300 50,000 zeny.^000000";
	close;
L_EXIT:
	mes "[Margaret Mary]";
	mes "Aww... well, OK then!";
	mes "Be pretty some other time";
	close;
}


//-------------------------------------------------------------------------------------------------
// Zherlthsh Mask (ID 5121)
gl_prison1.gat,138,141,4	script	Zherlthsh	1200,{
	mes "[Zherlthsh]";
	mes "Do you want an unique ^FF3300Zherlthsh Mask^000000?";
	next;
	menu "Yes, I do!",-,"No, thanks",L_EXIT;

	if(countitem(7315) < 369 || countitem(660) < 1 || countitem(7263) < 1 || countitem(7099) < 30) goto L_NOITEM;

	delitem 7315,369;	// Dark Crystal Fragment
	delitem 660,1;	// Forbidden Red Candle
	delitem 7263,1;	// Cat's Eye
	delitem 7099,30;	// Worn-out Magic Scroll
	getnameditem 5121,strcharinfo(0);
	logmes "Quest: Got Zherlthsh Mask";

	mes "[Zherlthsh]";
	mes "Just let me sign your unique Zealotus Mask.";
	mes "So all masks should be signed...";
	close;

L_NOITEM:
	mes "[Zherlthsh]";
	mes "All right. Bring me these items:";
	mes "^FF3300 369 Dark Crystal Fragment^000000,";
	mes "^FF3300 1 Forbidden Red Candle^000000,";
	mes "^FF3300 1 Cat's Eye^000000";
	mes "and ^FF3300 30 Worn-out Magic Scroll.^000000";
	close;

L_EXIT:
	mes "[Zherlthsh]";
	mes "As you wish...";
	close;
}