fRO_french_translation_rAthena/npc/battleground/flavius/flavius01.txt

//===== rAthena Script =======================================
//= Système de Champ de Bataille - Flavius
//===== Description: =========================================
//= [Conversion Officielle]
//= Champ de bataille de Flavius.
//= - Équipe gagnante : 9 badges (11 si VIP)
//= - Équipe perdante : 3 badges (5 si VIP)
//===== Traduction : =========================================
//= Traduit par OverSu et Liara
//===== Journal des modifications : ==========================
//= 1.0 Première version. [L0ne_W0lf]
//= 1.1 Correction de l'apparition du cristal rose en bleu. [L0ne_W0lf]
//= 1.2 Mise à jour de 'waitingroom' pour supporter le zeny/niveau requis. [Kisuka]
//= 1.3 Suppression de la vérification de niveau max dans les salles d'attente. Remplacement de setwall par setcell.
//= 1.4 Standardisation des étiquettes. [Euphy]
//= 1.5 Ajout d'une fonction de gestion pour les GMs. [Euphy]
//= 1.6 Ajout de fonctionnalités VIP et création d'une fonction de récompense. [Euphy]
//= 1.7 Cristaux rendus immunisés aux attaques tant que les Gardiens ne sont pas vaincus. [Cydh/Aleos]
//= 1.8 Ajout de vérifications battle_config pour permettre à ce script d’utiliser la nouvelle interface de file d’attente ou l’ancienne méthode. [Aleos]
//============================================================


// Salle d’attente des PNJ
//============================================================
bat_room,86,227,4	script	Lieutenant Ator	418,{
	end;
OnInit:
	waitingroom "Poste de combat",11,"start#bat_b01::OnReadyCheck",1,0,80;
	end;
OnEnterBG:
	set $@FlaviusBG1_id1, waitingroom2bg("bat_b01",10,290,"start#bat_b01::OnGuillaumeQuit","");
	end;
}

bat_room,85,204,0	script	Lieutenant Thelokus	414,{
	end;
OnInit:
	waitingroom "Poste de combat",11,"start#bat_b01::OnReadyCheck",1,0,80;
	end;
OnEnterBG:
	set $@FlaviusBG1_id2, waitingroom2bg("bat_b01",390,10,"start#bat_b01::OnCroixQuit","");
	end;
}

bat_room,85,220,0	warp	retour_bgroomb01a	1,1,bat_room,154,150
bat_room,85,211,0	warp	retour_bgroomb01b	1,1,bat_room,154,150

bat_room,2,151,3	script	#bat_b01_timer	844,{
	end;

OnInit:
	if (getbattleflag("feature.bgqueue"))
		end;
OnEnable:
	initnpctimer;
	end;

OnStop:
	stopnpctimer;
	end;

OnTimer1000:
	stopnpctimer;
	if (bg_get_data($@FlaviusBG1_id1, 0) == 0 && bg_get_data($@FlaviusBG1_id2, 0) == 0) {
		donpcevent "countdown#bat_b01::OnStop";
		if (getbattleflag("feature.bgqueue"))
			bg_reserve "bat_b01", true;
		$@FlaviusBG1 = 0;
		if( $@FlaviusBG1_id1 ) { bg_destroy $@FlaviusBG1_id1; $@FlaviusBG1_id1 = 0; }
		if( $@FlaviusBG1_id2 ) { bg_destroy $@FlaviusBG1_id2; $@FlaviusBG1_id2 = 0; }
		if (getbattleflag("feature.bgqueue"))
			bg_unbook "bat_b01";
		end;
	}
	initnpctimer;
	end;
}


// Moteur du Champ de bataille de Flavius
//============================================================
bat_b01,15,15,3	script	start#bat_b01	844,{
OnInit:
	if (getbattleflag("feature.bgqueue"))
		bg_unbook "bat_b01";
	mapwarp "bat_b01","bat_room",154,150;
	end;

OnReadyCheck:
	if( $@FlaviusBG1 )
		end;
	if (!getbattleflag("feature.bgqueue")) {
		set .@Guillaume, getwaitingroomstate(0,"Lieutenant Ator");
		set .@Croix, getwaitingroomstate(0,"Lieutenant Thelokus");
		if( !.@Guillaume && !.@Croix ) {
			donpcevent "#bat_b01_timer::OnStop";
			end;
		}
		if( .@Guillaume < 10 || .@Croix < 10 )
			end;
	}
	set $@FlaviusBG1, 1;
	set $@FlaviusBG1_Victory, 0;
	set $@Croix_ScoreBG1, 0;
	set $@Guill_ScoreBG1, 0;
	bg_updatescore "bat_b01",$@Guill_ScoreBG1,$@Croix_ScoreBG1;

	if (!getbattleflag("feature.bgqueue")) {
		donpcevent "Lieutenant Ator::OnEnterBG";
		donpcevent "Lieutenant Thelokus::OnEnterBG";
	}
	donpcevent "OBJ#bat_b01_a::OnKill";
	donpcevent "OBJ#bat_b01_a::OnEnable";
	donpcevent "OBJ#bat_b01_b::OnKill";
	donpcevent "OBJ#bat_b01_b::OnEnable";
	donpcevent "guardian#bat_b01_a::OnKill";
	donpcevent "guardian#bat_b01_b::OnKill";
	donpcevent "guardian#bat_b01_a::OnEnable";
	donpcevent "guardian#bat_b01_b::OnEnable";
	donpcevent "cell#bat_b01_a::OnRed";
	donpcevent "cell#bat_b01_b::OnRed";
	donpcevent "time#bat_b01::OnEnable";
	disablenpc "Guillaume Vintenar#b01_a";
	disablenpc "Croix Vintenar#b01_b";
	disablenpc "Vintenar#bat_b01_aover";
	disablenpc "Vintenar#bat_b01_bover";
	bg_warp $@FlaviusBG1_id1,"bat_b01",87,75;
	bg_warp $@FlaviusBG1_id2,"bat_b01",311,224;
	donpcevent "countdown#bat_b01::OnEnable";
	initnpctimer;
	end;

OnReset:
	donpcevent "OBJ#bat_b01_a::OnKill";
	donpcevent "OBJ#bat_b01_a::OnEnable";
	donpcevent "OBJ#bat_b01_b::OnKill";
	donpcevent "OBJ#bat_b01_b::OnEnable";
	donpcevent "guardian#bat_b01_a::OnKill";
	donpcevent "guardian#bat_b01_b::OnKill";
	donpcevent "guardian#bat_b01_a::OnEnable";
	donpcevent "guardian#bat_b01_b::OnEnable";
	donpcevent "cell#bat_b01_a::OnRed";
	donpcevent "cell#bat_b01_b::OnRed";
	end;


OnGuillaumeActive:
	warp "bat_b01",87,75;
	end;

OnCroixActive:
	warp "bat_b01",311,224;
	end;

OnGuillaumeQuit:
OnCroixQuit:
	if (getbattleflag("feature.bgqueue"))
		bg_desert;
	else
		bg_leave;
	end;

OnTimer10000:
	stopnpctimer;
	donpcevent "#bat_b01_timer::OnEnable";
	end;
}

bat_b01,1,1,3	script	OBJ#bat_b01_a	844,{
OnEnable:
	$@FlavBG1_C1_ID = bg_monster($@FlaviusBG1_id1,"bat_b01",61,150,"Cristal Rose",1915,"OBJ#bat_b01_a::OnMyMobDead");
	setunitdata $@FlavBG1_C1_ID,UMOB_DMGIMMUNE,1; // Rendre le Cristal immunisé tant que les Gardiens sont vivants
	end;

OnKill:
	killmonster "bat_b01","OBJ#bat_b01_a::OnMyMobDead";
	end;

OnMyMobDead:
	if (mobcount("bat_b01","OBJ#bat_b01_a::OnMyMobDead") < 1) {
		mapannounce "bat_b01", "Le cristal de Guillaume a été détruit.",bc_map,"0xFFCE00";
		if ($@Croix_ScoreBG1 > 0) {
			set $@FlaviusBG1_Victory,2;
			set $@Croix_ScoreBG1,$@Croix_ScoreBG1+1;
			enablenpc "Guillaume Vintenar#b01_a";
			enablenpc "Croix Vintenar#b01_b";
			donpcevent "time#bat_b01::OnStop";
			if (getbattleflag("feature.bgqueue"))
				bg_reserve "bat_b01", true;
		}
		else {
			set $@Croix_ScoreBG1,1;
			donpcevent "time#bat_b01::OnEnable";
			donpcevent "start#bat_b01::OnReset";
		}
		donpcevent "#bat_b01_timer::OnStop";
		bg_updatescore "bat_b01",$@Guill_ScoreBG1,$@Croix_ScoreBG1;
		bg_warp $@FlaviusBG1_id1,"bat_b01",10,290;
		bg_warp $@FlaviusBG1_id2,"bat_b01",390,10;
		donpcevent "#bat_b01_timer::OnEnable";
	}
	end;
}

bat_b01,1,2,3	script	OBJ#bat_b01_b	844,{
OnEnable:
	$@FlavBG1_C2_ID = bg_monster($@FlaviusBG1_id2,"bat_b01",328,150,"Cristal Bleu",1914,"OBJ#bat_b01_b::OnMyMobDead");
	setunitdata $@FlavBG1_C2_ID,UMOB_DMGIMMUNE,1; // Rendre le Cristal immunisé tant que les Gardiens sont vivants
	end;

OnKill:
	killmonster "bat_b01","OBJ#bat_b01_b::OnMyMobDead";
	end;

OnMyMobDead:
	if (mobcount("bat_b01","OBJ#bat_b01_b::OnMyMobDead") < 1) {
		mapannounce "bat_b01", "Le cristal de Croix a été détruit.",bc_map,"0xFFCE00";
		if ($@Guill_ScoreBG1 > 0) {
			set $@FlaviusBG1_Victory,1;
			set $@Guill_ScoreBG1,$@Guill_ScoreBG1+1;
			enablenpc "Guillaume Vintenar#b01_a";
			enablenpc "Croix Vintenar#b01_b";
			donpcevent "time#bat_b01::OnStop";
			if (getbattleflag("feature.bgqueue"))
				bg_reserve "bat_b01", true;
		}
		else {
			set $@Guill_ScoreBG1,1;
			donpcevent "time#bat_b01::OnEnable";
			donpcevent "start#bat_b01::OnReset";
		}
		donpcevent "#bat_b01_timer::OnStop";
		bg_updatescore "bat_b01",$@Guill_ScoreBG1,$@Croix_ScoreBG1;
		bg_warp $@FlaviusBG1_id1,"bat_b01",10,290;
		bg_warp $@FlaviusBG1_id2,"bat_b01",390,10;
		donpcevent "#bat_b01_timer::OnEnable";
	}
	end;
}


bat_b01,1,3,3	script	guardian#bat_b01_a	844,{
OnEnable:
	bg_monster $@FlaviusBG1_id1,"bat_b01",108,159,"Gardien du Camp de Guillaume",1949,"guardian#bat_b01_a::OnMyMobDead";
	bg_monster $@FlaviusBG1_id1,"bat_b01",108,141,"Gardien du Camp de Guillaume",1949,"guardian#bat_b01_a::OnMyMobDead";
	end;

OnKill:
	killmonster "bat_b01","guardian#bat_b01_a::OnMyMobDead";
	end;

OnMyMobDead:
	if (mobcount("bat_b01","guardian#bat_b01_a::OnMyMobDead") < 1) {
		donpcevent "cell#bat_b01_a::OnGreen";
		mapannounce "bat_b01", "Le Gardien protégeant le Cristal de Guillaume a été tué.",bc_map,"0xFFCE00";
		setunitdata $@FlavBG1_C1_ID,UMOB_DMGIMMUNE,0; // Le cristal peut maintenant être endommagé
	}
	end;
}

bat_b01,1,3,3	script	guardian#bat_b01_b	844,{
OnEnable:
	bg_monster $@FlaviusBG1_id2,"bat_b01",307,160,"Gardien du Camp de Croix",1949,"guardian#bat_b01_b::OnMyMobDead";
	bg_monster $@FlaviusBG1_id2,"bat_b01",307,138,"Gardien du Camp de Croix",1949,"guardian#bat_b01_b::OnMyMobDead";
	end;

OnKill:
	killmonster "bat_b01","guardian#bat_b01_b::OnMyMobDead";
	end;

OnMyMobDead:
	if (mobcount("bat_b01","guardian#bat_b01_b::OnMyMobDead") < 1) {
		donpcevent "cell#bat_b01_b::OnGreen";
		mapannounce "bat_b01", "Le Gardien protégeant le Cristal de Croix a été tué.",bc_map,"0xFFCE00";
		setunitdata $@FlavBG1_C2_ID,UMOB_DMGIMMUNE,0; // Le cristal peut maintenant être endommagé
	}
	end;
}


bat_b01,1,4,3	script	cell#bat_b01_a	844,{
OnRed:
	setcell "bat_b01",62,149,60,151,cell_basilica,1;
	setcell "bat_b01",62,149,60,151,cell_walkable,0;
	end;

OnGreen:
	setcell "bat_b01",62,149,60,151,cell_basilica,0;
	setcell "bat_b01",62,149,60,151,cell_walkable,1;
	end;
}

bat_b01,1,5,3	script	cell#bat_b01_b	844,{
OnRed:
	setcell "bat_b01",327,151,329,149,cell_basilica,1;
	setcell "bat_b01",327,151,329,149,cell_walkable,0;
	end;

OnGreen:
	setcell "bat_b01",327,151,329,149,cell_basilica,0;
	setcell "bat_b01",327,151,329,149,cell_walkable,1;
	end;
}

bat_b01,1,6,1	script	time#bat_b01	844,{
OnEnable:
	donpcevent "Thérapeute de Bataille#b01_a::OnEnable";
	donpcevent "Thérapeute de Bataille#b01_b::OnEnable";
	end;

OnStop:
	donpcevent "Thérapeute de Bataille#b01_a::OnStop";
	donpcevent "Thérapeute de Bataille#b01_b::OnStop";
	end;
}

bat_b01,10,294,3	script	Thérapeute de Bataille#b01_a	95,{
	specialeffect2 EF_HEAL;
	mes "[Thérapeute de Bataille]";
	mes "Ferme les yeux,";
	mes "et respire profondément.";
	mes "Tu peux être libéré de la douleur.";
	close;

OnTimer25000:
	specialeffect EF_SANCTUARY;
	areapercentheal "bat_b01",0,280,20,300,100,100;
	areawarp "bat_b01",0,280,20,300,"bat_b01",87,73;
	end;

OnTimer26500:
	stopnpctimer;
	donpcevent "Thérapeute de Bataille#b01_a::OnEnable";
	end;

OnEnable:
	initnpctimer;
	enablenpc "Thérapeute de Bataille#b01_a";
	end;

OnStop:
	disablenpc "Thérapeute de Bataille#b01_a";
	stopnpctimer;
	end;
}

/*
// replaced by areapercentheal and areawarp to prevent enqueue issue
bat_b01,10,290,0	script	bat_b01_rp1_a_warp	45,10,10,{
OnInit:
	disablenpc "bat_b01_rp1_a_warp";
	end;

OnTouch:
	percentheal 100,100;
	warp "bat_b01",87,73;
	end;
}
*/

bat_b01,389,14,3	script	Thérapeute de Bataille#b01_b	95,{
	specialeffect2 EF_HEAL;
	mes "[Thérapeute de Bataille]";
	mes "Ferme les yeux,";
	mes "et respire profondément.";
	mes "Tu peux être libéré de la douleur.";
	close;

OnTimer25000:
	specialeffect EF_SANCTUARY;
	areapercentheal "bat_b01",379,0,399,20,100,100;
	areawarp "bat_b01",379,0,399,20,"bat_b01",312,225;
	end;

OnTimer26500:
	stopnpctimer;
	donpcevent "Thérapeute de Bataille#b01_b::OnEnable";
	end;

OnEnable:
	initnpctimer;
	enablenpc "Thérapeute de Bataille#b01_b";
	end;

OnStop:
	disablenpc "Thérapeute de Bataille#b01_b";
	stopnpctimer;
	end;
}

bat_b01,87,76,0	script	A_CODE#bat_b01	-1,5,5,{
OnTouch:
	if (checkquest(2070) < 0)
		setquest 2070;
	end;
}

bat_b01,312,224,0	script	B_CODE#bat_b01	-1,5,5,{
OnTouch:
	if (checkquest(2070) < 0)
		setquest 2070;
	end;
}

bat_b01,10,294,3	script	Guillaume Vintenar#b01_a	934,{
	if ($@FlaviusBG1_id1 == getcharid(4)) {
		if ($@FlaviusBG1_Victory == 1)
			callfunc "F_BG_Badge",1,"Guillaume","Flavius";
		else
			callfunc "F_BG_Badge",0,"Guillaume","Flavius";
	}
	bg_leave;
	if (!getbattleflag("feature.bgqueue"))
		warp "bat_room",154,150;
	end;

OnInit:
	disablenpc "Guillaume Vintenar#b01_a";
	end;
}

bat_b01,389,14,3	script	Croix Vintenar#b01_b	934,{
	if ($@FlaviusBG1_id2 == getcharid(4)) {
		if ($@FlaviusBG1_Victory == 2)
			callfunc "F_BG_Badge",1,"Croix","Flavius";
		else
			callfunc "F_BG_Badge",0,"Croix","Flavius";
	}
	bg_leave;
	if (!getbattleflag("feature.bgqueue"))
		warp "bat_room",154,150;
	end;

OnInit:
	disablenpc "Croix Vintenar#b01_b";
	end;
}


bat_b01,1,5,3	script	countdown#bat_b01	844,{
OnInit:
	stopnpctimer;
	end;

OnEnable:
	stopnpctimer;
	initnpctimer;
	end;

OnStop:
	stopnpctimer;
	end;

OnTimer7000:
	mapannounce "bat_b01", "Guillaume Vintenar Axl Rose : Attaquons pour détruire ce cristal !",bc_map,"0xFF9900";
	end;

OnTimer8000:
	mapannounce "bat_b01", "Croix Vintenar Swandery : Même si Guillaume peine à gagner contre nous, la victoire est nôtre. Montrons-leur notre puissance.",bc_map,"0xFF99CC";
	end;

OnTimer1800000:
	mapannounce "bat_b01", "Marollo VII : Guillaume Marollo, Croix Marollo ! Et leurs partisans !",bc_map,"0x99CC00";
	end;

OnTimer1803000:
	mapannounce "bat_b01", "Marollo VII : Les deux camps sont compétitifs, il est difficile de dire lequel est supérieur.",bc_map,"0x99CC00";
	end;

OnTimer1808000:
	mapannounce "bat_b01", "Marollo VII : Cette bataille flavienne est une perte de temps. Je déciderai de la victoire selon vos performances.",bc_map,"0x99CC00";
	end;

OnTimer1822000:
	mapannounce "bat_b01", "Marollo VII : Si vous refusez ce résultat, retentez votre chance dans une autre vallée !",bc_map,"0x99CC00";
	end;

OnTimer1825000:
	mapannounce "bat_b01", "Axl Rose, Swandery : Oui, Monseigneur.",bc_map,"0x99CC00";
	end;

OnTimer1830000:
	donpcevent "time#bat_b01::OnStop";
	bg_warp $@FlaviusBG1_id1,"bat_b01",10,290;
	bg_warp $@FlaviusBG1_id2,"bat_b01",390,10;
	enablenpc "Vintenar#bat_b01_aover";
	enablenpc "Vintenar#bat_b01_bover";
	if (getbattleflag("feature.bgqueue"))
		bg_reserve "bat_b01", true;
	end;

OnTimer1900000:
	mapwarp "bat_b01","bat_room",154,150;
	donpcevent "countdown#bat_b01::OnStop";
	end;
}

bat_b01,10,294,3	script	Vintenar#bat_b01_aover	419,{
	set .@A_B_gap,$@Guill_ScoreBG1 - $@Croix_ScoreBG1;
	if ($@FlaviusBG1_id1 == getcharid(4)) {
		if (.@A_B_gap > 0)
			callfunc "F_BG_Badge",1,"Guillaume","Flavius"; // Guillaume gagne
		else if (.@A_B_gap == 0)
			callfunc "F_BG_Badge",0,"Guillaume","Flavius"; // Égalité
		else
			callfunc "F_BG_Badge",0,"Guillaume","Flavius"; // Croix gagne
	}
	else {
		mes "[Axl Rose]";
		mes "Que fais-tu ici, mercenaire de Croix ? Je suis certain de la victoire contre des imbéciles comme toi. Ha !";
		close;
	}
	bg_leave;
	if (!getbattleflag("feature.bgqueue"))
		warp "bat_room",154,150;
	end;

OnInit:
	disablenpc "Vintenar#bat_b01_aover";
	end;
}

bat_b01,389,14,3	script	Vintenar#bat_b01_bover	415,{
	set .@A_B_gap,$@Guill_ScoreBG1 - $@Croix_ScoreBG1;
	if ($@FlaviusBG1_id2 == getcharid(4)) {
		if (.@A_B_gap > 0)
			callfunc "F_BG_Badge",0,"Croix","Flavius"; // Guillaume gagne
		else if (.@A_B_gap == 0)
			callfunc "F_BG_Badge",0,"Croix","Flavius"; // Égalité
		else
			callfunc "F_BG_Badge",1,"Croix","Flavius"; // Croix gagne
	}
	else {
		mes "[Swandery]";
		mes "Pourquoi viens-tu ici en tant que Guillaume ? Retourne là où est ta place !";
		close;
	}
	bg_leave;
	if (!getbattleflag("feature.bgqueue"))
		warp "bat_room",154,150;
	end;

OnInit:
	disablenpc "Vintenar#bat_b01_bover";
	end;
}

bat_b01,81,83,3	script	Camp Guillaume#drapeau21	973,{ end; }
bat_b01,94,83,3	script	Camp Guillaume#drapeau22	973,{ end; }
bat_b01,81,66,3	script	Camp Guillaume#drapeau23	973,{ end; }
bat_b01,94,66,3	script	Camp Guillaume#drapeau24	973,{ end; }
bat_b01,139,142,3	script	Camp Guillaume#drapeau25	973,{ end; }
bat_b01,139,158,3	script	Camp Guillaume#drapeau26	973,{ end; }
bat_b01,110,161,3	script	Camp Guillaume#drapeau27	973,{ end; }
bat_b01,110,137,3	script	Camp Guillaume#drapeau28	973,{ end; }
bat_b01,63,135,3	script	Camp Guillaume#drapeau29	973,{ end; }
bat_b01,63,165,3	script	Camp Guillaume#drapeau30	973,{ end; }
bat_b01,10,296,3	script	Camp Guillaume#drapeau31	973,{ end; }

bat_b01,306,233,3	script	Camp Croix#drapeau21	974,{ end; }
bat_b01,317,233,3	script	Camp Croix#drapeau22	974,{ end; }
bat_b01,306,216,3	script	Camp Croix#drapeau23	974,{ end; }
bat_b01,317,216,3	script	Camp Croix#drapeau24	974,{ end; }
bat_b01,257,158,3	script	Camp Croix#drapeau25	974,{ end; }
bat_b01,257,141,3	script	Camp Croix#drapeau26	974,{ end; }
bat_b01,297,164,3	script	Camp Croix#drapeau27	974,{ end; }
bat_b01,297,136,3	script	Camp Croix#drapeau28	974,{ end; }
bat_b01,336,161,3	script	Camp Croix#drapeau29	974,{ end; }
bat_b01,336,139,3	script	Camp Croix#drapeau30	974,{ end; }
bat_b01,389,16,3	script	Camp Croix#drapeau31	974,{ end; }

bat_b01,1,10,3	script	Tout Libérer#b01	81,{
	set .@i, callfunc("F_GM_NPC",1854,0);
	if (.@i == -1) {
		mes "Annulé.";
		close;
	} else if (.@i == 0) {
		end;
	} else {
		mes "Puis-je vous aider ?";
		next;
		switch(select("Libérer tout le monde.:Annuler.")) {
		case 1:
			mes "Au revoir.";
			close2;
			mapwarp "bat_b01","bat_room",154,150;
			end;
		case 2:
			mes "Annulé.";
			close;
		}
	}
}

// La file d'attente de BG rend ces scripts inutiles
-	script	InitialisationBGFileAttente#flavius01	-1,{
	end;

OnInit:
	if (getbattleflag("feature.bgqueue")) {
		unloadnpc "Lieutenant Ator";
		unloadnpc "Lieutenant Thelokus";
		unloadnpc "back_bgroomb01a";
		unloadnpc "back_bgroomb01b";
		unloadnpc "A_CODE#bat_b01";
		unloadnpc "B_CODE#bat_b01";
	}
	end;
}