//===== rAthena Script =======================================
//= Einbroch Airport Staff (Traduction FR par OverSu & Liara, 2025-04)
//===== Par : ==================================================
//= L0ne_W0lf, Muad_Dib
//===== Traduction : ============================================
//= OverSu & Liara T'Soni (Respect du ton et univers de RO)
//===== Compatible Avec : ======================================
//= rAthena Project
//===== Description : ==========================================
//= Personnel de l'aéroport d'Einbroch
//==============================================================

airport,143,43,5	script	Airport Staff#airport1a::airport1	90,{
	mes "[Personnel Aéroportuaire]";
	mes "Bienvenue à l'aéroport";
	mes "d'Einbroch, où nous proposons";
	mes "des vols directs vers les villes";
	mes "de Juno, Lighthalzen et Hugel.";
	next;
	if (select("Monter à bord du dirigeable:Annuler") == 1) {
		mes "[Personnel Aéroportuaire]";
		mes "L'embarquement coûte 1 200 zeny,";
		mes "mais si vous possédez un Billet Gratuit";
		mes "pour Dirigeable, les frais seront annulés.";
		mes "Souhaitez-vous embarquer ?";
		next;
		if (select("Oui:Non") == 1) {
			if (countitem(7311) > 0) {
				delitem 7311,1; //Free_Flying_Ship_Ticket
				warp "airport",148,51;
				end;
			}
			if (Zeny >= 1200) {
				set Zeny, Zeny - 1200;
				warp "airport",148,51;
				end;
			}
			mes "[Personnel Aéroportuaire]";
			mes "Désolé, vous ne possédez pas de";
			mes "Billet Gratuit pour Dirigeable et";
			mes "vous n'avez pas assez de zeny";
			mes "pour embarquer. Le tarif est de";
			mes "1 200 zeny.";
			close;
		}
	}
	mes "[Personnel Aéroportuaire]";
	mes "Merci, et passez une excellente journée.";
	close;
}

airport,158,43,5	duplicate(airport1)	Airport Staff#airport1b	90
airport,126,43,5	duplicate(airport1)	Airport Staff#airport1c	90

airport,143,49,3	script	Arrival Staff#airport2a::airport2	90,{
	mes "[Agent d'Accueil]";
	mes "Bienvenue à l'aéroport d'Einbroch.";
	mes "Si vous venez d'arriver par vol,";
	mes "je peux vous guider vers le terminal principal.";
	mes "Sinon, veuillez embarquer pour Juno,";
	mes "Lighthalzen ou Hugel.";
	next;
	if (select("Sortir vers le terminal principal.:Annuler.") == 1) {
		mes "[Agent d'Accueil]";
		mes "Une fois au terminal principal,";
		mes "vous devrez repayer les frais d'embarquement";
		mes "si vous souhaitez repartir. Ne sortez que";
		mes "si Einbroch est bien votre destination.";
		mes "Souhaitez-vous continuer ?";
		next;
		if (select("Oui:Non") == 1) {
			warp "airport",142,40;
			end;
		}
	}
	mes "[Agent d'Accueil]";
	mes "Très bien, merci pour votre confiance,";
	mes "et nous vous souhaitons un excellent vol~";
	close;
}

airport,126,51,3	duplicate(airport2)	Arrival Staff#airport2b	90
airport,158,50,3	duplicate(airport2)	Arrival Staff#airport2c	90

einbroch,94,267,3	script	Airship Staff#ein01	91,{
	mes "[Personnel Aéroportuaire]";
	mes "Bienvenue à l'aéroport d'Einbroch.";
	mes "Veuillez utiliser cette porte pour embarquer";
	mes "sur le dirigeable desservant Juno,";
	mes "Lighthalzen et Hugel dans la République de Schwarzwald.";
	next;
	mes "[Personnel Aéroportuaire]";
	mes "Sinon, si Einbroch est votre destination,";
	mes "descendez les escaliers et adressez-vous";
	mes "au personnel d'accueil pour rejoindre le terminal principal.";
	mes "Merci, et bon voyage.";
	close;
}