//===== eAthena Script ======================================= 
//= Baphomet Jr. taming item quest.
//===== By: ================================================== 
//= eAthena Dev Team
//===== Current Version: ===================================== 
//= 1.2
//===== Compatible With: ===================================== 
//= eAthena 1.0
//===== Description: ========================================= 
//= Book of Devil		(MISC_QUEST | 256)
//===== Additional Comments: ================================= 
//= 1.0 ????
//= 1.1 Optimized Book of Devil quest. used bit-wise var. [Lupus]
//= 1.2 Fixed name collision with 'Little Boy' in cities/lutie.txt [Ai4rei]
//============================================================ 

//=============================================================
//Quest for Book of Devil
//=============================================================
niflheim,184,199,5	script	Little Girl#02	793,{
	mes "[Sairin]";
	if(MISC_QUEST & 256){
		mes "Thanks again!";
		close;
	}
	if(@niflheimlost == 2){
		mes "You found him?";
		mes "Oh thank you!";
		mes "Please, take this as a token of my appreciation.";
		getitem 642,1;//Items: Book of Devil,
		set MISC_QUEST,MISC_QUEST | 256;
		set @niflheimlost,0;
		close;
	}
	if(@niflheimlost == 1){
M_YES:
		set @niflheimlost,1;
		mes "Please find him and tell him where I am! I saw him last in Niflheim Field, the first one...";
		close;
	}
	mes "Sir, will you please help me?";
	if(BaseJob==Job_Novice){
		mes "Oh... you are lost, too...";
		close;
	}
	next;
	menu "Yes",-, "No",M_NO;

	mes "[Sairin]";
	mes "My friend and I went for a hike and ended up wandering into a strange field.";
	next;
	mes "[Sairin]";
	mes "Suddenly, I found a doll. I picked it up, and it turned into a ghost!";
	next;
	mes "[Sairin]";
	mes "I screamed and ran as fast as I could. When I stopped running, I ended up in this strange town..";
	next;
	mes "[Sairin]";
	mes "No one here will help me, and there are ghosts everywhere! Could you help me find my friend?";
	next;
	menu "Sure",M_YES, "No",M_NO;
M_NO:
	close;
}

nif_fild01,213,268,5	script	Little Boy#02	797,{
	if(MISC_QUEST & 256){
L_DONE:
		set @niflheimlost,2;
		mes "[Marius]";
		mes "Thank you for helping us!";
		close;
	}
	if(@niflheimlost == 2) goto L_PART2;
	if(@niflheimlost == 1){
		mes "[Marius]";
		mes "Who are you?";
		mes "...";
		mes "You found Sairin?";
		mes "She ran to Niflheim?";
		next;
L_PART2:
		mes "[Marius]";
		mes "Could you tell her that I am on my way?";
		mes "I am a little slow, and its very important that she knows.";
		next;
		menu "Yes",L_DONE, "No",-;
		close;	
	}
	mes "[Marius]";
	mes "Sairin... where are you?";
	close;
}
