//===== eAthena Script ======================================= 
//= Einbroch Airport Staff
//===== By: ================================================== 
//= L0ne_W0lf, Muad_Dib
//===== Current Version: ===================================== 
//= 1.3
//===== Compatible With: ===================================== 
//= eAthena Revision 3000+
//===== Description: ========================================= 
//= Einbroch Airport Staff
//===== Additional Comments: ================================= 
//= Converted by Dr.Evil, 1.0b more typos and credits [Lupus]
//= 1.1 Fixed wrong check, added extra condition [Justin84]
//= 1.2 Removed Duplicates [Silent]
//= 1.3 Fixed syntax errors for duplicate [KarLaeda]
//============================================================


airport,126,43,4	script	Airport Staff#01::AirportE	90,{
	mes "[Airport Staff]";
	mes "Welcome to the Airport.";
	mes "How may I help you?";
	next;
	menu "Board the Airship",-,"Cancel",L_Cancel;

		mes "[Airport Staff]";
		mes "The Airship boarding fee";
		mes "is 1,200 zeny, but if you've";
		mes "got a Free Ticket for Airship,"; 
		mes "the fee will be waived. Will";
		mes "you board the Airship?";
		next;
		menu "Yes",-,"No",L_Cancel;

		if(countitem(7311) > 0) goto L_GotTicket;
		if(Zeny < 1200) goto L_NoZeny;
			set Zeny, Zeny - 1200;
			warp "airport",148,51;
			close;

		L_GotTicket:
			delitem 7311,1;
			warp "airport",148,51;
			close;

	L_NoZeny:
		mes "[Airport Staff]";
		mes "You don't have enough zeny.";
		close;

	L_Cancel:
		mes "[Airport Staff]";
		mes "Thank you and";
		mes "have a nice day.";
		close;
}

airport,143,43,4	duplicate(AirportE)	Airport Staff#02	90
airport,156,43,4	duplicate(AirportE)	Airport Staff#03	90

airport,126,51,4	script	Airport Staff#04::AirportE2	90,{
	mes "[Airport Staff]";
	mes "Welcome~";
	mes "Please head this";
	mes "way to board the Airship.";
	next;
	menu "Exit to Main Terminal",-,"Cancel",L_Cancel;

		mes "[Airport Staff]";
		mes "If you leave the";
		mes "main terminal, you'll";
		mes "have to pay the admission";
		mes "fee again in order to board";
		mes "the Airship. Are you sure";
		mes "that you want to exit?";
		next;
		menu "Yes",-,"No",L_Cancel;

			warp "airport",142,40;
			close;

	L_Cancel:
		mes "[Airport Staff]";
		mes "Alright, thank you";
		mes "for your patronage";
		mes "and I hope you have";
		mes "a pleasant flight~";
		close;
}

airport,143,51,4	duplicate(AirportE2)	Airport Staff#05	90
airport,156,51,4	duplicate(AirportE2)	Airport Staff#06	90

einbroch,94,267,4	script	Airship Staff	91,{
	mes "[Airship Staff]";
	mes "Welcome to the";
	mes "Einbroch Airport.";
	mes "Please use this door to";
	mes "board the Airship wich stops";
	mes "over Lighthalzen and Juno in";
	mes "the Schwarzwald Republic";
	next;
	mes "[Airship Staff]";
	mes "Otherwise, if Einbroch is";
	mes "your intended destination,";
	mes "please head down the stairs";
	mes "and ask the Arrival Staff to lead";
	mes "you to the main terminal. Thank";
	mes "you, and enjoy your travels.";
	close;
}
