//===== eAthena Script =======================================
//= War of Emperium (Prontera)
//===== By: ==================================================
//= L0ne_W0lf
//===== Current Version: =====================================
//= 1.3
//===== Compatible With: =====================================
//= eAthena SVN
//===== Description: =========================================
//= NPCs that relate to Prontera Guild Castle 1
//===== Additional Comments: =================================
//= 1.0 First Version. No longer uses functions. [L0ne_W0lf]
//= 1.1 Corrected flag-in spawn point. [L0ne_W0lf]
//= 1.2 Corrected treasure room switch coordinates. [L0ne_W0lf]
//= 1.3 Removed dialog from interior flags. [L0ne_W0lf]
//============================================================

// Guild Flag (Town)
//============================================================
prontera,165,194,5	script	Gondul#p5-1::Gondul	722,{
	end;

OnRecvCastlePt05:
	FlagEmblem GetCastleData("prtg_cas05",1);
	end;
}

// Guild Flag (Outside Castle)
//============================================================
prt_gld,199,243,2	script	Gondul#p5-2::Gondul2	722,{
	set .@GID, GetCastleData("prtg_cas05",1);
	if (.@GID == 0) {
		mes " [ Edict of the Divine Rune Midgard Kingdom ]";
		mes " ";
		mes "1. Follow the ordinance of The Divine Rune Midgard Kingdom, ";
		mes "We declare that";
		mes "there is no formal master of this castle.";
		mes " ";
		mes "2. To the one who can ";
		mes "overcome all trials";
		mes "and destroy the Emperium,";
		mes "the king will endow the one with";
		mes "ownership of this castle.";
	}
	else {
		if (getcharid(2) == .@GID) {
			mes "Brave ones...";
			mes "Do you wish to return to your honorable place?";
			next;
			if (select("Return to the guild castle.:Quit.") == 1) {
				if (getcharid(2) == GetCastleData("prtg_cas05",1)) {
					warp "prtg_cas05",52,41;
					end;
				}
			}
			close;
		}
		mes "[ Edict of the Divine Rune Midgard Kingdom ]";
		mes " ";
		mes "1. Following the ordinance of the";
		mes "Divine Rune Midgard Kingdom,";
		mes "we approve that this place is in";
		mes "the private possession of ^ff0000" + GetGuildName(.@GID) + "^000000 Guild.";
		mes " ";
		mes "2. The guild Master of ^ff0000"+ GetGuildName(.@GID) + "^000000 Guild is";
		mes "^FF0000" + GetGuildMaster(.@GID) + "^000000";
		mes "If there is anyone who objects to this,";
		mes " prove your strength and honor with a steel blade in your hand.";
	}
	close;

OnRecvCastlePt05:
	FlagEmblem GetCastleData("prtg_cas05",1);
	end;
}

prt_gld,199,236,2	duplicate(Gondul2)	Gondul#p5-3	722
prt_gld,197,243,2	duplicate(Gondul2)	Gondul#p5-4	722
prt_gld,197,236,2	duplicate(Gondul2)	Gondul#p5-5	722

// Guild Flag (Inside Castle)
//============================================================
prtg_cas05,19,247,4	script	Gondul#p5-6::Gondul3	722,{
	end;

OnRecvCastlePt05:
	FlagEmblem GetCastleData("prtg_cas05",1);
	end;
}

prtg_cas05,19,243,4	duplicate(Gondul3)	Gondul#p5-7	722
prtg_cas05,26,247,4	duplicate(Gondul3)	Gondul#p5-8	722
prtg_cas05,26,243,4	duplicate(Gondul3)	Gondul#p5-9	722
prtg_cas05,249,289,4	duplicate(Gondul3)	Gondul#p5-10	722
prtg_cas05,256,289,4	duplicate(Gondul3)	Gondul#p5-11	722
prtg_cas05,253,271,4	duplicate(Gondul3)	Gondul#p5-12	722
prtg_cas05,273,257,4	duplicate(Gondul3)	Gondul#p5-13	722

// AGIT Manager
//============================================================
prtg_cas05,266,266,0	duplicate(Gld_Agit_Manager)	Agit#prtg_cas05	-1

// Steward
//============================================================
prtg_cas05,36,37,4	duplicate(Gld_Mngr_Template)	Raynor#prtg_cas05	55

// Guardians
//============================================================
prtg_cas05,36,37,4	duplicate(Gld_Guard_Template)	Guardian#prtg_cas05	-1

// Kafra Staff
//============================================================
prtg_cas05,52,41,4	duplicate(Gld_Kafra_Template)	Kafra Staff#prtg_cas05	117

// Master's Room Exit
//============================================================
prtg_cas05,281,176,0	script	#switch_Pt05	111,{
	mes " ";
	mes "There's a small lever. Will you pull it? ";
	next;
	switch(select("Pull.:Do not.")) {
	case 1:
		warp "prtg_cas05",36,38;
		break;
	case 2:
		break;
	}
	end;
}

// Guild Treasure Protection
//============================================================
prtg_cas05,276,178,0	duplicate(Gld_Trea_Protect)	ban_warp#prtg_cas05	-1,6,6

// Guild Treasure Spawns
//============================================================
prtg_cas05,276,178,0	duplicate(Gld_Trea_Spawn)	Treasure#prtg_cas05	-1

// Guild Dungeon Switch
//============================================================
prtg_cas05,212,94,0	duplicate(Gld_Dun_Template)	#prtg_cas05	111
