//===== eAthena Script ======================================= 
//= Alberta Guides
//===== By: ================================================== 
//= kobra_k88
//===== Current Version: ===================================== 
//= 1.1
//===== Compatible With: ===================================== 
//= eAthena  0.5.2 +
//===== Description: ========================================= 
//=
//===== Additional Comments: ================================= 
//= Fully working
//= v1.1 Now using duplicate command.
//============================================================ 




// North --------------------------------------------------------
alberta.gat,23,238,4	script	Guide#1::Guide	105,{
	cutin "prt_soldier",2;
	mes "[Alberta Soldier]";
	mes "Welcome to Alberta, the Port Town.";
	next;
	mes "[Alberta Soldier]";
	mes "We are here to help you find your way.  Please feel free to speak to us anytime.";
	mes "Oh, and if you're a newbie you should read the notice first.";
M_Menu:
	next;
	menu "View Buildings",M_1, "Notice",M_2, "Cancel",M_End;

	M_1:
		mes "[Alberta Soldier]";
		mes "Do you want me to leave indications on the Mini-Map?";
		next;
		menu "No Thanks",sM_1a,"Yes Please",sM_1b;
		
		sM_1a:
			set @COMPASS_CHECK,0;
			goto L_Cont;
		sM_1b:
			set @COMPASS_CHECK,1;

		L_Cont:
		mes "[Alberta Soldier]";
		mes "Please choose a building to view.";
		next;
	sM_Menu:
		menu "^FF0000Merchant Guild^000000",sM_2a,"Armory",sM_2b,"Item Shop",sM_2c,"Inn",sM_2d, "Wipe all indications from mini-map.",sM_2e, "Cancel",M_End;

		sM_2a:
			mes "[Alberta Soldier]";
			mes "The 'Merchant Guild' is located in the SouthWestern part of town.  The Merchant Guild is the place to go to become a merchant.";
			viewpoint 1,33,41,1,0xFF0000;
			goto sL_Wipe;
		sM_2b:
			mes "[Alberta Soldier]";
			mes "The 'Armory' is located in the Southern part of town.  Go there to buy weapons and armor.";
			viewpoint 1,148,57,2,0x6666FF;
			goto sL_Wipe;
		sM_2c:
			mes "[Alberta Soldier]";
			mes "The 'Item Shop' is located in the Centre of town.";
			viewpoint 1,98,154,3,0xFF00FF;
			goto sL_Wipe;
		sM_2d:
			mes "[Alberta Soldier]";
			mes "There are 2 'Inns' located in the Northern and Southern parts of town.  Go there if you need to rest.";
			viewpoint 1,65,233,4,0xF5AD05;
			viewpoint 1,136,38,5,0xF5AD05;
			goto sL_Wipe;
		sM_2e:
			set @COMPASS_CHECK, 2;

		sL_Wipe:
			if(@COMPASS_CHECK != 2) next;
			if(@COMPASS_CHECK == 1) goto sM_Menu;
			viewpoint 2,33,41,1,0xFF0000;
			viewpoint 2,148,57,2,0x6666FF;
			viewpoint 2,98,154,3,0xFF00FF;
			viewpoint 2,65,233,4,0xF5AD05;
			viewpoint 2,136,38,5,0xF5AD05;
			if(@COMPASS_CHECK == 0) goto sM_Menu;
			mes "[Alberta Soldier]";
			mes "All indications have been removed";
			cutin "prt_soldier",255;
			close;

	M_2:
		mes "[Alberta Soldier]";
		mes "We upgraded the Location Guide to the newest Digital Style.  We hope you like this gorgeous new system.";
		next;
		mes "[Alberta Soldier]";
		mes "Don't forget to refer to the Mini-Map on the Upper-Right corner of your screen.";
		next;
		mes "[Alberta Soldier]";
		mes "If you can't see the Mini-Map, just hit ^0000ff'ctrl+tab'^000000 or Click the ^0000ff'map'^000000 button in the Basic Information Window";
		mes "Remeber to use the ^ff0000+,-^000000 buttons to adjust the map to your liking.";
		goto M_Menu;

	M_End:
		mes "[Alberta Soldier]";
		mes "Ta Ta.";
		cutin "prt_soldier",255;
		close;
}

// South --------------------------------------------------------
alberta.gat,120,60,3	duplicate(Guide)	Guide#2	105
