//===== eAthena Script =======================================
//= Berzebub Card Quest Script
//===== By: ==================================================
//= jabs <jabbedxorz@hotmail.com>
//===== Current Version: =====================================
//= 1.0
//===== Compatible With: =====================================
//= Any eAthena Version; RO Episode XX
//===== Description: =========================================
//= Quest to get the Berzebub Card
//===== Additional Comments: =================================
//= MINE
//============================================================
prontera.gat,165,178,8	script	Old Woman	103,{
	if(BerzQuest == 1) goto alreadyDone;
	mes "[Old Woman]";
	mes "Greeting lad. I found a really nift item while I was picking mushrooms near Glast Heim";
	next;
	menu "Keep talking", goOn, "Leave", leave;
	
	leave:
		mes "[Old Woman]";
		mes "Such a great item I have right here...";
		close;
		
	goOn:
		mes "[Old Woman]";
		mes "I have never seen an item like this before.  I am told it can be placed inside am accessory that has a slot avaiable in it.";
		next;
		mes "[Old Woman]";
		mes "If you're interested in this item, tell me and I'll tell you what you need for me to make you one of your own.  I can only give one of these to each player, so once you finish this quest once, you may not do it again.";
		next;
		menu "Tell me more about it", getInfo, "Nah, I don't care about it", leave;
		
	getInfo:
		mes "[Old Woman]";
		mes "I believe the item is called a Berzebub Card.  It can make any spell caster cast spells really fast!";
		next;
		mes "[Old Woman]";
		mes "I need all of the following items:";
		mes "^0080FF10^000000 Emperium";
		mes "^0080FF100^000000 Witched Starsand";
		mes "^0080FF200^000000 Needle of Alarm";
		mes "^0080FF10^000000 Worn Out Scrolls";
		mes "^0080FF1^000000 Bible";
		mes "^0080FF1^000000 Wand of the Occult";
		mes "^0080FF20^000000 Opal";
		next;
		menu "I have all that!", checkItems, "I'll get those ASAP", leave;
		
	checkItems:
		mes "[Old Woman]";
		mes "Anyone can say they have the items, but do they really have them?  Let's take a look here...";
		next;
		if(countitem(714) < 10) goto noItems;
		if(countitem(1061) < 100) goto noItems;
		if(countitem(1095) < 200) goto noItems;
		if(countitem(618) < 10) goto noItems;
		if(countitem(1551) < 1) goto noItems;
		if(countitem(1614) < 1) goto noItems;
		if(countitem(727) < 20) goto noItems;
		delitem 714, 10;
		delitem 1061, 100;
		delitem 1095, 200;
		delitem 618, 10;
		delitem 1551, 1;
		delitem 1614, 1;
		delitem 727, 20;
		getitem 4145, 1;
		set BerzQuest, 1;
		mes "[Old Woman]";
		mes "Well congratulations!  You have all the items.  Here is your Berzebub Card, just as I promised.";
		close;
	
	noItems:
		mes "[Old Woman]";
		mes "I knew you were lying!  Get out of here and get those items you sorry excuse for a rock star.";
		close;
	
	alreadyDone:
		mes "[Old Woman]";
		mes "Hey I remember you!  I already told you that you may only complete this quest once.";
		close;
}
