//===== eAthena Script ======================================= 
//= Soul Linker Job Quest
//===== By: ================================================== 
//= Celestria
//===== Current Version: ===================================== 
//= 1.1
//===== Compatible With: ===================================== 
//= eAthena 1.0 +
//===== Description: ========================================= 
//= 
//===== Additional Comments: ================================= 
//= A temp Soul Linker Job Changer based on the kRO quest.
//= Quest info from RagnaInfo. Sprites from kRO screenshots
//= 1.0	Optimized and updated [Lupus]
//= 1.1 Fixed NPC names according to iRO [Lupus]
//============================================================ 

morocc_in,174,30,7	script	Kid#sltest	716,{
	if(SOUL_Q==1) goto L_Check;
	if(SOUL_Q >= 2) goto L_Warp;
	if(Class==Job_Soul_Linker) goto L_Thanks;
	mes "[Kid]";
	mes "*sniff sniff*";
	next;
	if((Class==Job_Taekwon) && (JobLevel>=40)) goto L_Taekwon;
	mes "The little boy is crying and";
	mes "it doesn't look like you're";
	mes "going to be able to stop him.";
	close;

L_Thanks:
	mes "[Kid]";
	mes "Hey, Thank you for helping";
	mes "me earlier ^_^";
	close;

L_Taekwon:
	mes "[Kid]";
	mes "Excuse me. *sniff*";
	mes "I don't suppose you couldvhelp me?";
	next;
	menu "Go on...",L_Goon,"No, I'm busy.",L_No;

L_No:
	mes "[Kid]";
	mes "Waaaaaaaaaaaaaah~";
	close;

L_Goon:
	mes "[Kid]";
	mes "Well you see, I was doing some";
	mes "shopping for my daddy, who's";
	mes "an alchemist, and on my way home";
	mes "a thief came and took my shopping!";
	next;
	menu "I'll get you your stuff.",-,"Awww, that's too bad.",L_No;
	mes "[Kid]";
	mes "Really!?";
	mes "You'll do that for me?";
	set SOUL_Q,1;
	next;
	mes "[Kid]";
	mes "Ok, what I need is:";
	mes "^0000FF- 1 3-Carat Diamond^000000";
	mes "^0000FF- 1 Witherless Rose^000000";
	mes "^0000FF- 1 Immortal Heart^000000";
	next;
	mes "[Kid]";
	mes "Please find these things quickly...";
	close;

L_Check:
	if(countitem(748) < 1 || countitem(732) < 1 || countitem(929) < 1) goto L_Noitem;
	delitem 748,1;
	delitem 732,1;
	delitem 929,1;
	set SOUL_Q,2;
	if(SkillPoint) goto L_Skill;
	mes "[Kid]";
	mes "Wow, Thank you so much!";
	mes "You're so helpful, I think I";
	mes "know of a few other people";
	mes "who could use your help.";
	next;
	menu "Lead the way.",L_Warp,"Umm... Not right now.",-;
	mes "[Kid]";
	mes "Okay, come back when you change your mind.";
	close;

L_Noitem:
	mes "[Kid]";
	mes "Awww... you haven't found all the items yet.";
	next;
	mes "[Kid]";
	mes "Remember, it was:";
	mes "^0000FF- 1 3-Carat Diamond^000000";
	mes "^0000FF- 1 Witherless Rose^000000";
	mes "^0000FF- 1 Immortal Heart^000000";
	next;
	mes "[Kid]";
	mes "Please find these things quickly...";
	close;

L_Warp:
	if(SkillPoint) goto L_Skill;
	mes "[Kid]";
	mes "Okay, here we go.";
	close2;
	warp "job_soul",30,30;
	end;

L_Skill:
	mes "[Kid]";
	mes "It seems you have some skill";
	mes "points left. I can't warp you";
	mes "to my friends until you use them.";
	close;
}

job_soul,30,35,2	script	Lost Soul#1	827,{
	if(SOUL_Q==2) goto L_Talk1;
	mes "[Lost Soul]";
	mes "I have said all I have needed to say. Thank you.";
	close;

L_Talk1:
	mes "[Lost Soul]";
	mes "Welcome to the lost plane";
	mes "This is where souls of";
	mes "those who have passed on";
	mes "go if they have not yet";
	mes "let go of what they believe";
	mes "they were meant to do.";
	next;
	mes "[Lost Soul]";
	mes "I am here because I wanted";
	mes "to protect people with my";
	mes "strong arms.";
	next;
	mes "[Lost Soul]";
	mes "Yet they were not strong";
	mes "enough to protect myself";
	mes "and those I truly loved...";
	next;
	mes "[Lost Soul]";
	mes "So now I float here in";
	mes "death, reflecting on the past";
	mes "and how it could have been";
	mes "different had I been stronger.";
	next;
	mes "[Lost Soul]";
	mes "But with time I have decided";
	mes "that dwelling on the past";
	mes "accomplishes nothing.";
	mes "Only actions can protect";
	mes "those around you.";
	next;
	mes "[Lost Soul]";
	mes "You!!";
	mes "You seem strong.";
	mes "I shall join you, and add";
	mes "My strength to yours so";
	mes "that you might protect others.";
	set SOUL_Q,3;
	next;
	mes "[Lost Soul]";
	mes "Thank you for hearing me out.";
	close;
}

job_soul,25,30,3	script	Lost Soul#2	744,{
	if(SOUL_Q==3) goto L_Talk2;
	if(SOUL_Q < 3) goto L_Notyet2;
	mes "[Lost Soul]";
	mes "I have said all I have";
	mes "needed to say. Thank you.";
	close;

L_Notyet2:
	mes "[Lost Soul]";
	mes "Please talk to the others first.";
	close;

L_Talk2:
	mes "[Lost Soul]";
	mes "It seems that you already know where you are.";
	next;
	mes "[Lost Soul]";
	mes "I am here because I wanted";
	mes "to cure the sick an injured";
	mes "with my herbs and potions.";
	next;
	mes "[Lost Soul]";
	mes "But I was inexperienced";
	mes "and accidentally mixed";
	mes "ingrediants I should not have...";
	next;
	mes "[Lost Soul]";
	mes "Those I was trying to save,";
	mes "myself, and families in the";
	mes "close vicinity all in flames";
	mes "because of my incompetance.";
	next;
	mes "[Lost Soul]";
	mes "I've spent years here furious";
	mes "at myself for making that one";
	mes "simple mistake.";
	next;
	mes "[Lost Soul]";
	mes "Sure, lots of people make";
	mes "mistakes, but seldom on that scale.";
	mes "And so I shall join you, so as to";
	mes "be a guiding voice, reminding you";
	mes "that you should always prethink";
	mes "your own actions.";
	set SOUL_Q,4;
	next;
	mes "[Lost Soul]";
	mes "Thank you for hearing me out.";
	close;
}

job_soul,30,25,0	script	Lost Soul#3	754,{
	if(SOUL_Q==4) goto L_Talk3;
	if(SOUL_Q < 4) goto L_Notyet3;
	mes "[Lost Soul]";
	mes "I have said all I have needed to say. Thank you.";
	close;

L_Notyet3:
	mes "[Lost Soul]";
	mes "Please talk to the others first.";
	close;

L_Talk3:
	mes "[Lost Soul]";
	mes "I guess it's time for my story...";
	next;
	mes "[Lost Soul]";
	mes "Study. Study. Study.";
	mes "All I ever did was study.";
	next;
	mes "[Lost Soul]";
	mes "Oh! The things I learnt.";
	mes "My vocabulary was larger than";
	mes "others, I new the names of all";
	mes "the local plants, I even helped";
	mes "in the writing of the code for";
	mes "the AI Guardian, Apocolypse.";
	next;
	mes "[Lost Soul]";
	mes "But in all my time studying";
	mes "I never made any time for";
	mes "friends, and never spent any";
	mes "time with my family.";
	next;
	mes "[Lost Soul]";
	mes "It wasn't until one day when I got sick from lack of sleep and";
	mes "no one came to my aid, that I realised just how lonely I was.";
	next;
	mes "[Lost Soul]";
	mes "So I wish to join with you.";
	mes "I shall be that gentle reminder";
	mes "that no matter how important";
	mes "something is to you, you must";
	mes "always make time for friends and family.";
	set SOUL_Q,5;
	next;
	mes "[Lost Soul]";
	mes "Thank you for hearing me out.";
	close;
}

job_soul,35,30,3	script	Kid#4	716,{
	if(SOUL_Q < 5) goto L_Notyet4;
	mes "[Kid]";
	mes "So you have listened to the tales of my friends?";
	next;
	mes "[Kid]";
	mes "They aren't bad people they've just been depressed for so very long.";
	next;
	mes "[Kid]";
	mes "But they seem to have renewed vigour since they talked to you.";
	mes "I haven't seen them this lively ever.";
	next;
	mes "[Kid]";
	mes "You seem to have a gift with people, so with your permisson,";
	mes "I would like to make you a Soul Linker.";
	next;
	menu "Yes",-,"No",L_Warpout;

	mes "[Kid]";
	mes "Very Well then.";
	mes "You are now a Soul Linker.";
	jobchange Job_Soul_Linker;
	callfunc "F_ClearJobVar";
	misceffect 247;
	next;
	mes "[Kid]";
	mes "Please try to help others.";
	close2;
	warp "morocc_in",175,31;
	end;

L_Warpout:
	mes "[Kid]";
	mes "If you change your mind come and talk to me.";
	close2;
	warp "morocc_in",175,31;
	end;

L_Notyet4:
	mes "[Kid]";
	mes "Please talk to the others first.";
	close;	
}