//===== eAthena Script ======================================= 
//= Quest NPCs related to Niflheim
//===== By: ================================================== 
//= Evera and The eAthena Dev Team
//===== Current Version: ===================================== 
//= 1.0
//===== Compatible With: ===================================== 
//= eAthena 7.15 +
//===== Description: ========================================= 
//= Book of Devil and Piano Key quest
//===== Additional Comments: ================================= 
//= 1.0 Initial release, moved Book of Devil and Piano quest from npc/cities/niflheim.txt [Evera]
//============================================================ 

//=============================================================
//Quest for Book of Devil
//=============================================================
niflheim.gat,184,199,5	script	Little Girl#02	793,{
	mes "[Sairin]";
	if(niflheimlost2 == 1) goto L_thanks;
	if(niflheimlost == 1) goto L_foundhim;
	if(lostgirl == 1) goto L_sure2;
	mes "Sir, will you please help me?";
	if(BaseJob==Job_Novice) mes "Oh... you are lost, too..."; //Exploit fix
	if(BaseJob==Job_Novice) close;
	next;
	menu "Yes",-, "No",M_no;

	mes "[Sairin]";
	mes "My friend and I went for a hike and ended up wandering into a strange field.";
	next;
	mes "[Sairin]";
	mes "Suddenly, I found a doll. I picked it up, and it turned into a ghost!";
	next;
	mes "[Sairin]";
	mes "I screamed and ran as fast as I could. When I stopped running, I ended up in this strange town..";
	next;
	mes "[Sairin]";
	mes "No one here will help me, and there are ghosts everywhere! Could you help me find my friend?";
	next;
	menu "Sure",-, "No",M_no;
L_sure2:
	set lostgirl,1;
	mes "Please find him and tell him where I am! I saw him last in Niflheim Field, the first one...";
	close;

L_foundhim:
	mes "You found him?";
	mes "Oh thank you!";
	mes "Please, take this as a token of my appreciation.";
	getitem 642,1;//Items: Book of Devil,
	set niflheimlost2,1;
	close;
L_thanks:
	mes "Thanks again!";
M_no:
	close;
}

//=============================================================
//Piano Quest
//=============================================================
niflheim.gat,224,243,3	script	Alager	795,{
	mes "[Alager]";
	mes "Muahaha, I love to eat meat...";
	mes "You look... delicious!";
	next;
	mes "[Alager]";
	mes "I'm going to eat you...";
	next;
	mes "-Chomp bite slurp-";
	if (nif_quest1 == 1 || (MISC_QUEST & 32)) goto L_end;
	percentheal -60,0;
	next;
	mes "[Alager]";
	mes "Ahhh, it's been some time since I had such delicious meat!";
	// 50% made up, not the slightest idea how to translate these ^^;
	mes "as an ex-barbeque chef, my favourite meat";
	mes "would be like preparing beef fillet,";
	mes "crossed and grilled to perfection";
	mes "that would be really delicious... ";
	next;
	mes "[Alager]";
	mes "Ah, let me thank you with this,";
	mes "I found it on the ground, hoho~";
	getitem 7184,1;//Items: Piano Key,
	set nif_quest1, 1;
	close;
L_end:
	percentheal -30,0;
 	close;
}

nif_in.gat,105,81,3	script	Crayu	794,{
	mes "[Crayu]";
	mes "Ah, there was this poem...";
	mes "in which author and time of writing was unknown,";
	mes "and has been circulating since long ago...";
	next;
	mes "[Crayu]";
	mes "^FF0000When the sun sets in the western hills,^000000";
	mes "^FF0000Where points the velvet gloom of dawn,^000000";
	mes "^FF0000The beautiful melody surrounding thy soul,^000000";
	mes "^FF0000Is the key from Lord Death's wrath.^000000";
	next;
	if (nif_quest2 == 1 || (MISC_QUEST & 32)) goto L_end;
	set @nif_random,rand(1,4);
	mes "[Crayu]";
	mes "Heh, let me give you a little exam!";
	mes "Repeat line no. " + @nif_random + " of the poem";
	mes "that you have just heard to me!";
	next;
	input @inputstr1$;
	if (@nif_random == 2) goto L_RAN_2;
	if (@nif_random == 3) goto L_RAN_3;
	if (@nif_random == 4) goto L_RAN_4;
	//if (@nif_random == 1) goto L_RAN_1;	
	L_RAN_1:
		set @str1$,"When the sun sets in the western hills,";
		goto L_RAN_B;
	
	L_RAN_2:
		set @str1$,"Where points the velvet gloom of dawn,";
		goto L_RAN_B;

	L_RAN_3:
		set @str1$,"The beautiful melody surrounding thy soul,";
		goto L_RAN_B;

	L_RAN_4:
		set @str1$,"Is the key from Lord Death's wrath.";
		goto L_RAN_B;

	L_RAN_B:
		if (@inputstr1$ == @str1$) goto L_RAN_SC;
		mes "[Crayu]";
		mes "Aih... If you had paid more attention,";
		mes "you would have known the correct answer!";
		mes "Come back for the challenge again,";
		mes "when you have thought over it!";
		close;

	L_RAN_SC:
		mes "[Crayu]";
		mes "Hoho... I see you have paid attention!";
		mes "I am Grey, a wandering poet of yore,";
		mes "you are the best audience I have had so far,";
		mes "here, take this as a reward.";
		getitem 7184,1;//Items: Piano Key,
		set nif_quest2, 1;
		next;
		mes "[Crayu]";
		mes "I hope you will treat other poets";
		mes "as well as you treated me, farewell.";
		close;

L_end:
	mes "[Crayu]";
	mes "I wonder what does it mean...";
	mes "If you read it carefully,";
	mes "it seems to have a deep meaning,";
	mes "as if there is a mysterious secret";
	mes "hidden within these words...";
	close;
}

nif_in.gat,31,20,3	script	Kurtz	794,{
	mes "[Kurtz]";
	mes "Business nowadays is really bad...";
	mes "Back when I used to be alive,";
	mes "my business was this bad too~!";
	if (nif_quest3 == 1 || (MISC_QUEST & 32)) close;
	next;
	mes "[Kurtz]";
	mes "Hey! You there! Dump this for me";
	mes "on the way out will you!";
	getitem 7184,1;//Items: Piano Key,
	set nif_quest3, 1;
	next;
	mes "[Kurtz]";
	mes "Why is business so bad lately...";
	mes "(mumble mumble)";
	close;
}

niflheim.gat,169,71,5	script	#1	111,2,2{
	if (MISC_QUEST & 32 || nif_quest4 == 1) end;

	mes "- In the nearby tombs -";
	mes "- you see something -";
	mes "- half buried in the ground -";
	mes "- What is it? -";
	mes "- Looks like it broke off something -";
	next;
	mes "- Pick it up? -";
	menu "Yes",-,"No",L_end;
	getitem 7184,1;//Items: Piano Key,
	set nif_quest4, 1;
L_end:
	close;
}

niflheim.gat,208,103,5	script	#2	111,2,2{
	if (MISC_QUEST & 32) end;
	if (nif_quest5 == 1) goto L_key2;
	if (nif_quest5 >= 2) end;

	mes "- In the nearby tombs -";
	mes "- you see something -";
	mes "- half buried in the ground -";
	mes "- What is it? -";
	mes "- Looks like it broke off something -";
	next;
	mes "- Pick it up? -";
	menu "Yes",-,"No",L_end;
	getitem 7184,1;//Items: Piano Key,
	set nif_quest5, 1;
	close;
L_key2:
	mes "- In the hole you have dug -";
	mes "- there is something else -";
	mes "- buried deep in the ground -";
	mes "- Looks like its another fragment -";
	next;
	mes "- Pick it up? -";
	menu "Yes",-,"No",L_end;
	getitem 7184,1;//Items: Piano Key,
	set nif_quest5, 2;
L_end:
	close;
}

nif_in.gat,115,181,5	script	#4	111,3,3{
	mes "- You see a huge old piano -";
	if ((MISC_QUEST & 32)==0) mes "- with a few keys missing  -";
	if (MISC_QUEST & 32) mes "- with one key missing -";
	if ((MISC_QUEST & 32)==0 && countitem(7184) > 5) goto L_event;//Items: Piano Key,
	close;

L_event:
	delitem 7184,6;//Items: Piano Key,
	set MISC_QUEST,MISC_QUEST | 32;
	//clear auxiliary vars now
	set nif_quest1, 0;
	set nif_quest2, 0;
	set nif_quest3, 0;
	set nif_quest4, 0;
	set nif_quest5, 0;
	set nif_random,0; //clear garbage from the previous version of the script
	set nif_random1,0; //clear garbage
	mes "- You slide the 6 piano keys one -";
	mes "- by one into the missing slots  -";
	mes "- on the piano, but you realize  -";
	mes "- the left-most side seems to be -";
	mes "- missing one more key. -";
	close;
}

nif_in.gat,118,151,5	script	#5	111,3,3{
	if((MISC_QUEST & 32)==0) end;

	mes "- The very moment the long shadow -";
	mes "- of your body falls on the piano -";
	next;
	mes "- You suddenly seem to feel lighter -";
	mes "- and your vision starts to blur... -";
	next;
	warp "nif_in.gat",179,163;
	close;
}

nif_in.gat,188,168,3	script	Witch	792,{
	mes "[Kirkena]";
	mes "Hmm?... Aren't you a living human?";
	mes "Must have took you some effort";
	mes "to get to this place...";
	mes "Whatever reason though, this is not a place";
	mes "the living shall belong...";
	next;
	mes "[Kirkena]";
	mes "I shall use my powers to send you back";
	mes "but you should not return in the future.";
	close2;
	warp "umbala.gat",138,208;
	end;
}