//===== eAthena Script ======================================= 
//= Quest NPCs related to Alberta
//===== By: ================================================== 
//= kobra_k88
//===== Current Version: ===================================== 
//= 1.7
//===== Compatible With: ===================================== 
//= eAthena 1.0
//===== Description: ========================================= 
//= Dolls Quest
//= Boy's Cap Quest
//= Antlers Quest
//= Bao Bao, Cresent Hairpin, Fashionbale Glasses, Heart Hairpin Quests
//= Hat of Sun God, Sunday Hat, Mage Hat, Magician Hat Quests
//= Turtle Island Quests
//===== Additional Comments: ================================= 
//= Fully working
//= 1.1 Fixed Spore Doll exploit, Gramp's Tiger skin label bug
//= 1.3 Fixed item ID 7031 -> 7013
//= 1.4 Fixed a bug, Fixed Exploits, Optimized [Lupus]
//= 1.6 TEMPESTRA quest uses common quests variable MISC_QUEST 
//=	Condition if done: (MISC_QUEST & 2) [Lupus]
//= 1.7 Moved quest from cities/albera.txt [Evera]
//============================================================ 



//=======================================================================================================//
//						Doll Quest
//=======================================================================================================//
alberta.gat,117,134,8	script	Elin	96,{
	mes "[Elin]";
	if(Sex){
		mes "Hello, mister. Hmm, since you're a boy, you don't like dolls, do you?";
	}else{
		mes "Hello, miss. Since you're a girl, you must like dolls, don't you?";
	}
	next;
	mes "[Elin]";
	mes "I LOVE dolls!!";
	emotion e_lv2;
	next;
	mes "[Elin]";
	mes "Ya know..... I REALLY, REALLY, want a new doll.  I hope daddy is going to buy me one for my birthday.....";
	next;
	menu "Aww, you must be happy...",-,"How about I give you one now?",M_2;

		mes "[Elin]";
		mes "Yeah, this time I'm hoping for a Yoyo doll.  Hehe, they're so cute! They're my FAVORITE!";
		emotion e_ok;
		close;
	M_2:
		mes "[Elin]";
		mes "Oh my goodness! Really?? You're such a sweetie.... gimme, gimme!!";
		mes "What kinda doll are you going to give me? Are you really gonna give me one?";
		emotion e_gasp;
		next;
		menu "Puppet",-,"Poring doll",sM_2,"Chonchon doll",sM_3,"Rocker doll",sM_4, "Spore doll",sM_5,
		           "Osiris doll",sM_6,"Baphomet doll",sM_7,"Racoon doll",sM_8,"Yoyo doll",sM_9, "I am as adorable as a doll!",sM_10;
		
			if(countitem(740) < 1) goto L_Liar;
			delitem 740,1;
			mes "[Elin]";
			mes "Wow--! It's a rabbit! It's SOOOO cute!! Thank you SOOO much!";
			emotion e_lv2;
			next;
			mes "[Elin]";
			mes "It's SOOO fluffy... Oh yeah! Let me give you a present too!";
			next;
			mes "(diggs around in her pockets)";
			next;
			mes "[Elin]";
			mes "Ummm ... found it! Here take this!";
			next;
			getitem 530,1;
			mes "[Elin]";
			mes "I got this from Santa. It's a candy cane~";
			next;
			mes "[Elin]";
			mes "Thanks again for the rabbit doll! I'm gonna HUG this to sleep EVERY night~";
			emotion e_thx;
			close;

		sM_2:
			if(countitem(741) < 1) goto L_Liar;
			delitem 741,1;
			mes "[Elin]";
			mes "Yay! It's a poring doll! It's SOOOO cute! Since you gave me a doll I'll give you this....";
			emotion e_lv2;
			next;
			getitem 529,1;
			mes "[Elin]";
			mes "Thank you for the doll!";
			emotion e_thx;
			close;

		sM_3:
			if(countitem(742) < 1) goto L_Liar;
			delitem 742,1;
			mes "[Elin]";
			mes "Ew whats this?.... a Chonchon ... doll? ...";
			emotion e_wah;
			next;
			mes "[Elin]";
			mes "Oh well, since you're giving it to me, I guess it's ok ....";
			next;
			mes "[Elin]";
			mes "Well here's a little something for giving me the doll.  Don't eat too much or you'll get cavities.";
			getitem 530,1;
			next;
			mes "[Elin]";
			mes ".... chonchon.... (~grumble, grumble~)";
			emotion e_ag;
			close;

		sM_4:
			if(countitem(752) < 1) goto L_Liar;
			delitem 752,1;
			mes "[Elin]";
			mes "Oh! a Rocker doll.  I hate hopping things but this doll's kinda cute.";
			next;
			mes "[Elin]";
			mes "Thank you.  Let me give you something too.";
			next;
			mes "[Elin]";
			mes "Hmm, didn't I get some stuff from my uncle ...";
			next;
			mes "[Elin]";
			mes "Here it is.  We've got tons of it at home so I'll share some with you~";
			getitem 532,7;
			next;
			mes "[Elin]";
			mes "Thanks again for the doll!";
			emotion e_thx;
			close;

		sM_5:
			if(countitem(743) < 1) goto L_Liar;
			delitem 743,1;
			mes "[Elin]";
			mes "Blehh .... It's a mushroom... Mom's always scolding me for not eating mushrooms ...";
			emotion e_swt;
			next;
			mes "[Elin]";
			mes "I'll take it anyway, since the doll looks cute.  But I still won't eat mushrooms though ...";
			next;
			mes "[Elin]";
			mes "Hmm, I'll need to give you a present too.";
			next;
			mes "[Elin]";
			mes "My mom made this so please take it.";
			getitem 538,5;
			next;
			mes "[Litte Kid]";
			mes "Thank you for the doll~";
			emotion e_thx;
			close;

		sM_6:
			if(countitem(751) < 1) goto L_Liar;
			delitem 751,1;
			mes "[Elin]";
			mes "Yay! It's an Osiris doll!";
			next;
			mes "[Elin]";
			mes "Here's something for you too.";
			getitem 522,2;
			mes "[Elin]";
			mes "Thank you for the doll!";
			close;

		sM_7:
			if(countitem(750) < 1) goto L_Liar;
			delitem 750,1;
			mes "[Elin]";
			mes "Yay! It's a Baphomet doll!";
			next;
			mes "[Elin]";
			mes "Here's something for you too.";
			getitem 525,5;
			mes "[Elin]";
			mes "Thank you for the doll!";
			emotion e_thx;
			close;

		sM_8:
			if(countitem(754) < 1) goto L_Liar;
			delitem 754,1;
			mes "[Elin]";
			mes "Ah, it's a Smokie doll.  I hate Smokies, but the doll's really cute! Thank you!";
			emotion e_ok;
			next;
			mes "[Elin]";
			mes "Let me give you some of Grandma's home-made cake!";
			getitem 539,3;
			next;
			mes "[Elin]";
			mes "They're really good so make sure you eat them ok.";
			next;
			mes "[Elin]";
			mes "Thanks again for this cute doll!";
			emotion e_thx;
			close;

		sM_9:
			if(countitem(753) < 1) goto L_Liar;
			delitem 753,1;
			mes "[Elin]";
			mes "WOW--!!! OH MY GOSH! It's a Yoyo doll! This is what I REALLY wanted!! It's SOOOO cute......";
			emotion e_lv2;
			next;
			mes "[Elin]";
			mes "As a thank you, I'll give you this.";
			getitem 608,1;
			next;
			mes "[Elin]";
			mes "Dad picked them up during his travels.  It's a seed of some kind.";
			mes "We tried planting them at home, but it doesn't seem to grow.";
			next;
			mes "[Elin]";
			mes "Anyway, thank you SOOO MUCH for the Yoyo doll!!!!";
			emotion e_thx;
			close;

		sM_10:
			mes "[Elin]";
			mes "BLAAAAAAAAHHH!! Don't make fun of me cuz I'm young!";
			emotion e_pif;
			next;
			mes "[Elin]";
			mes "(mumbles) .....'stupid'.....";
			close;

		L_Liar:
			mes "[Elin]";
			mes "HEY!! You don't have any dolls... I can't believe you would lie to a little kid!!!";
			emotion e_gasp;
			next;
			mes "[Elin]";
			mes "You're a MEANIE!! I HATE YOU!!!..... sniff... sniff.... Waaaaaaaaaaaaaaaaaaaahhhhhh!!";
			emotion e_sob;
			close;
}


//=======================================================================================================//
//						Boy's Cap' Quest
//=======================================================================================================//
alberta_in.gat,28,145,4	script	Grampa	120,{
	mes "[Grampa]";
	mes "Gasp ..Gasp";
	next;
	mes "[Grampa]";
	mes "When I look back on my younger days... I regret not making better use of my time...";
	next;
	mes "[Grampa]";
	mes "Even so I STILL feel young at heart..... unfortunately my body is very old and is in poor condtion...... Cough !! Cough .. !!";
	next;
	if(countitem(1030) >= 10) menu "Talk.",M_Talk, "Show him Tiger's Footskin.",M_Show, "Cancel.",M_End;
	menu "Talk",M_Talk, "Cancel",M_End;
	
	M_Talk:
		mes "[Grampa]";
		mes "Listen to me..... You must take care of your body as best you can....";
		mes "If you aren't serious about staying healthy now..... you will surely regret it as you get older.";
		next;
		mes "[Grampa]";
		mes "I've tried to restore my body to its youthful, healthy state with all of the best herbs and medicines that money can buy....";
		next;
		mes "[Grampa]";
		mes "Not only have none of them worked, but their emense cost have made me bankurpt!";
		next;
		mes "[Grampa]";
		mes "I have all but given up on trying to restore my youth.... there IS still one last thing I have not yet tried.....";
		next;
		mes "[Grampa]";
		mes "It is the ^3355FFTiger's Footskin^000000, the legendary king of rejuvination!!"; 
		emotion e_gasp;
		next;
		mes "[Grampa]";
		mes "Have you heard of the Tiger's Footskin???.....";
		emotion e_what;
		next;
		mes "[Grampa]";
		mes "Just by LOOKING at it, your white hair turns Black again! By SMELLING it, your reflexes become 10x faster!";
		mes "And just a single TASTE can turn and 80 year old man.... INTO AN 18 BOY!!!!";
		next;
		mes "[Grampa]";
		mes "It truely is amazing! Ah, if I could only get my hands on some Tiger's Footskin.... my wishes would at last come true.....";
		next;
		mes "[Grampa]";
		mes "For whoever brings me ^5555FF10 Tiger's Footskins^000000, I would gladly give that person my precious ^3355FFBoys Cap^000000.";
		close;

	M_Show:
		mes "[Grampa]";
		mes "Ohhh !! Th-This is the... this is the legendary.... TIGERS FOOTSKIN!!";
		next;
		mes "[Grampa]";
		mes "Just by LOOKING at it, your white hair turns Black again! By SMELLING it, your reflexes become 10x faster!";
		mes "And just a single TASTE can turn and 80 year old man.... INTO AN 18 BOY!!!!";
		next;
		mes "[Grampa]";
		mes "It is the real Tiger's Footskin !! In my wildest dreams I never thought...... P-P-Please.... I beg you.... let me have it.....";
		next;
		menu "-Give him the Tiger's Footskin.",-, "Walk away.", sM_End;

			mes "[Grampa]";
			if(countitem(1030) < 10) goto L_NoItems;
			delitem 1030,10;
			getitem 5016,1;
			mes "T-Thank YOU!! Thank you SO VERY MUCH!!";
			emotion e_thx;
			next;
			mes "[Grampa]";
			mes "Now my body can be reinvigorated!!! I will eat it right away!";
			close;

		L_NoItems:
			mes "Get off damn cheater!!!";
			emotion e_bzz;
			close;

		sM_End:
			mes "[Grampa]";
			mes "H-He-Hey!! Young one!! W-Wa-it! Please.... come back... I beg you.... come... back.... ooohh... foot.... sk... i... n....";
			close;

	M_End:
		mes "[Grampa]";
		mes "Cough Cough !! .. Tiger ....Tiger's ..... Foot ..... skin .....Cough Cough !!";
		close;


}


//=======================================================================================================//
//						Antlers Quest 
//=======================================================================================================//
alberta_in.gat,122,53,4	script	Cherokee	47,{
	mes "[Cherokee]";
	mes "Hey there, I am a Horn Collector.  Sounds great, huh?";
	next;
	mes "[Cherokee]";
	mes "What do you think about Animal horns? I think they are very valuable and are well worth collecting.";
	mes "You can wear them on your head, or even decorate your house with them.";
	next;
	mes "[Cherokee]";
	mes "You know.... there has been a particular horn that I have not been able to find.  It is the ^5555FF'Evil Horn '^000000..";
	next;
	mes "[Cherokee]";
	mes "Some say that an Evil Horn is really not an animal's horn, but one that comes from a Devil!";
	mes "Even so, I really wish I could get my hands on one.";
	next;
	mes "[Cherokee]";
	mes "Say.... do you have any ^5555FF'Evil Horns'^000000?";
	mes "If you offer me ^5533FF20 Evil Horns^000000, I will give you my precious and famed, ^FF3355'Antlers'^000000.  Is it a deal?";
	next;
	menu "You got it!",-, "Shut up Dumbo.",M_End;

		mes "[Cherokee]";
		if(countitem(923) < 20) goto L_NotEnuf;
		delitem 923,20;
		mes "Whoah~! This is the first time I've ever seen a real ^3355FF'Evil Horn'^000000!!";
		emotion e_ic;
		next;
		mes "[Cherokee]";
		mes "Thank you! Here are the Antlers just as I promised you!";
		emotion e_thx;
		getitem 2284,1;
		next;
		mes "[Cherokee]";
		mes "With your great help I was finally able to realize my long time dream.  I appreciate what you have done! God Bless You ..";
		close;

		L_NotEnuf:
			mes "Hmm.... like I said, I need ^FF5533'20 Evil Horns'^000000.";
			close;

	M_End:
		mes "[Cherokee]";
		mes "Well aren't you a rude person.... I will forgive you however, seeing as we will meet again, I'm sure....";
		close;
}


//=======================================================================================================//
//			Bao Bao, Cresent Hairpin, Fashionbale Glasses, Heart Hairpin
//=======================================================================================================//
alberta.gat,120,53,3	script	Zic	51,{
	mes "[Zic]";
	mes "Yay! A cool breeze! That's why I love the sea!!";
	emotion e_ho;
	next;
	mes "[Zic]";
	mes "Huh?... Do you have any business with me? You came to me because I'm a merchant right?";
	emotion e_hmm;
	next;
	mes "[Zic]";
	mes "~Sigh!~ I get tired of my reputation.... I can't get any peace or quite around here.....";
	next;
	mes "[Zic]";
	mes "So what do you wanna get? Tell me, tell me! It's so easy to guess what you want.....";
	next;
	menu "-Bao Bao",-, "-Cresent Hairpin",M_1, "-Fashionable Glasses",M_2, "-Heart Hairpin",M_3;

		mes "[Zic]";
		mes "To make a Bao Bao I will need:";	//5042
		mes "- ^5555FF1 Silk Ribbon^000000,";	//10007
		mes "- ^5555FF50 Herioc Emblems^000000.";	//968
		next;
		mes "[Zic]";
		mes "Would you like me to make you one?";
		next;
		menu "Sure.",-, "No thanks.",M_End;

			if (countitem(10007)<1 || countitem(968)<50) goto sL_NotEnuf;
			delitem 10007, 1;
			delitem 968, 50;
			mes "[Zic]";
			mes "Please wait while I make your Bao Bao......";
			next;
			mes "[Zic]";
			mes "There you are, one Bao Bao.  Enjoy.";
			getitem 5042, 1;
			close;
	M_1:
		mes "[Zic]";
		mes "To make a Cresent Hairpin I will need:";	//5048
		mes "- ^5555FF1 Heart Hair Pin^000000,";	//5041
		mes "- ^5555FF10 Steel^000000.";	//999
		next;
		mes "[Zic]";
		mes "Would you like me to make you one?";
		next;
		menu "Sure.",-, "No thanks.",M_End;

			if (countitem(5041)<1 || countitem(999)<10) goto sL_NotEnuf;
			delitem 5041, 1;
			delitem 999, 10;
			mes "[Zic]";
			mes "Please wait while I make your Cresent Hairpin......";
			next;
			mes "[Zic]";
			mes "There you are, one Cresent Hairpin.  Enjoy.";
			getitem 5048, 1;
			close;
	M_2:
		mes "[Zic]";
		mes "To make a pair of Fashionable Glasses I will need:";	//5047
		mes "- ^5555FF1 Jack a Dandy^000000,";	//2271
		mes "- ^5555FF1 Scarlet Dyestuffs^000000.";	//975
		next;
		mes "[Zic]";
		mes "Would you like me to make you one?";
		next;
		menu "Sure.",-, "No thanks.",M_End;

			if (countitem(2271)<1 || countitem(975)<1) goto sL_NotEnuf;
			delitem 2271, 1;
			delitem 975, 1;
			mes "[Zic]";
			mes "Please wait while I make your Fashionable Glasses......";
			next;
			mes "[Zic]";
			mes "There you are, one Fashionable Glasses.  Enjoy.";
			getitem 5047, 1;
			close;
	M_3:
		mes "[Zic]";
		mes "Are you sure you want a simple item like this? Oh well... To make a Heart Hairpin I will need:";	//5041
		mes "- ^5555FF1200 Coral Reefs^000000.";	//7013
		emotion e_hmm;
		next;
		mes "[Zic]";
		mes "Would you like me to make you one?";
		next;
		menu "Sure.",-, "No thanks.",M_End;

			if (countitem(7013)<1200) goto sL_NotEnuf;
			delitem 7013, 1200;
			mes "[Zic]";
			mes "Please wait while I make your Hear Hairpin......";
			next;
			mes "[Zic]";
			mes "There you are, one Heart Hairpin.  Enjoy.";
			getitem 5041, 1;
			close;

		sL_NotEnuf:
			mes "[Zic]";
			mes "Hmm.... you don't have enough items for me to make it.  Come back some other time.";
			close;

	M_End:
		mes "[Zic]";
		mes "See ya around.";
		close;
}


//=======================================================================================================//
//				Hat of Sun God, Sunday Hat, Mage Hat, Magician Hat
//=======================================================================================================//
alberta.gat,135,79,3	script	Tempestra	71,{
	mes "[Tempestra]";
	mes "Ah...... Such a cool breeze.  It's good to be next to the sea.  I think it was the right choice for me to take a break from my business and come here.";
	emotion e_ho;
	if(MISC_QUEST & 2) goto sM_Menu;
	next;
	mes "[Tempestra]";
	mes "Oh the sun is so bright today.  I'm glad I brought my hat.  If my skin is exposed to the sun like this everyday, I'm sure to get a sunburn.";
	next;
	mes "[Tempestra]";
	mes "Boy, the heat is making me thirsty.  Nothing would be better right now, than sipping on a perfectly chilled yellow potion.....";
	next;
	menu "Here you go, my treat.",-, "Then go get one, sheesh....",M_1;

		if(countitem(503) < 1) goto L_NoPot;
		delitem 503, 1;
		set MISC_QUEST,MISC_QUEST | 2;
		mes "[Tempestra]";
		mes "Oooh! Thank you so much.  I'm so glad to meet such a friendly person here....";
		emotion e_thx;
		next;
		mes "[Tempestra]";
		mes "(~gulp~gulp~)";
		next;
		mes "[Tempestra]";
		mes "Hyaaaaaaa!! It's sooo cold!! Thank you.";
	sM_Menu:
		next;
		menu "The weather is really hot, isn't it...",-, "You should wear a hat.",sM_1;

			mes "[Tempestra]";
			mes "Yes, it's very hot indeed.....";
			next;
			mes "[Tempestra]";
			mes "Luckly I brought a lot of hats along.  I have";
			mes "a ^5555FF'Sunday Hat'^000000,";
			mes "a ^5555FF'Mage Hat'^000000,";
			mes "a ^5555FF'Magician Hat'^000000, and more in my room...";
			next;
			mes "[Tempestra]";
			mes "I brought these hats with me so that I could sell them and use the money I made for my vacation expenses....";
			mes "but now it looks like I'll have to wear one.....";
		ssM_Menu:
			next;
			menu "Sunday Hat?",-, "Mage Hat?",ssM_0b, "Magician Hat?",ssM_0c, "End Conversation.",ssM_End;

				mes "[Tempestra]";
				mes "A Sunday Hat is made up of:";
				mes "- ^5555FF250 Fabric^000000,";
				mes "- ^5555FF1 Slotted Hat^000000,";
				mes "- ^5555FF1 Slotted Cap^000000,";
				mes "- ^5555FF600 Soft Feathers^000000.";
				mes "If you want, I can make one for you.  Just bring me all of those items.";
				next;
				menu "Make one for me.",-, "Cancel",ssM_End;

					if (countitem(1059)<250 || countitem(2221)<1 || countitem(2227)<1 || countitem(7063)<600) goto ssM_Menu;
					delitem 1059, 250;
					delitem 2221, 1;
					delitem 2227, 1;
					delitem 7063, 600;
					mes "[Tempestra]";
					mes "Please wait just a moment while I make it........";
					next;
					getitem 5032, 1;
					mes "[Tempestra]";
					mes "All done... one Sunday Hat just for you.  Thank you and come back any time.";
					emotion e_thx;
					close;
			ssM_0b:
				mes "[Tempestra]";
				mes "A Mage Hat is made up of:";
				mes "- ^5555FF1 Wizard Hat^000000,";
				mes "- ^5555FF400 Dragon Scales^000000,";
				mes "- ^5555FF50 Mould Powder^000000,";
				mes "- ^5555FF1 Elder Wilow Card^000000.";
				mes "If you want, I can make one for you.  Just bring me all of those items.";
				next;
				menu "Make one for me.",-, "Cancel",ssM_End;

					if (countitem(2252)<1 || countitem(1036)<400 || countitem(7001)<50 || countitem(4052)<1) goto ssM_Menu;
					delitem 2252, 1;
					delitem 1036, 400;
					delitem 7001, 50;
					delitem 4052, 1;
					mes "[Tempestra]";
					mes "Please wait just a moment while I make it........";
					next;
					getitem 5027, 1;
					mes "[Tempestra]";
					mes "All done... one Mage Hat just for you.  Thank you and come back any time.";
					emotion e_thx;
					close;
			ssM_0c:
				mes "[Tempestra]";
				mes "A Magician Hat is made up of:";
				mes "- ^5555FF1 Wizard Hat^000000,";
				mes "- ^5555FF450 Ancient Lips^000000,";
				mes "- ^5555FF1200 Solid Shells^000000,";
				mes "If you want, I can make one for you.  Just bring me all of those items.";
				next;
				menu "Make one for me.",-, "Cancel",ssM_End;

					if (countitem(2252)<1 || countitem(1054)<450 || countitem(943)<1200) goto ssM_Menu;
					delitem 2252, 1;
					delitem 1054, 450;
					delitem 943, 1200;
					mes "[Tempestra]";
					mes "Please wait just a moment while I make it........";
					next;
					getitem 5045, 1;
					mes "[Tempestra]";
					mes "All done... one Magician just for you.  Thank you and come back any time.";
					emotion e_thx;
					close;
			ssM_End:
				close;

		sM_1:
			mes "[Tempestra]";
			mes "Oh but the hats I have are for sale.... if I use them for myself I won't be able to sell them to my customers.";
			next;
			mes "[Tempestra]";
			mes "Because you gave me the potion, I would like to make something for you.  Unfortuately I don't have any materials right now.";
			next;
			mes "[Tempestra]";
			mes "Hmm... If you have:";
			mes "^5555FF1 Emblem of the Sun God";
			mes "10 Gold";
			mes "40 Steel";
			mes "50 Coal";
			mes "and 2 Oridecon^000000..........";
			next;
			mes "[Tempestra]";
			mes "I can make you a ^5555FF'Hat of the Sun God'^000000!! It's a fantastic piece of work! How's that sound?";
			next;
			menu "Alright.",-, "Not right now thanks.",ssM_1b;

				if(countitem(7086)<1 || countitem(969)<10 || countitem(999)<40 || countitem(1003)<50 || countitem(984)<2) goto ssL_NotEnuf;
				delitem 7086, 1;
				delitem 969, 10;
				delitem 999, 40;
				delitem 1003, 50;
				delitem 984, 2;
				mes "[Tempestra]";
				mes "Please wait just a moment while I make it........";
				next;
				getitem 5022, 1;
				mes "[Tempestra]";
				mes "All done... one Hat of the Sun God just for you.  Thank you again for the potion, and please come back any time.";
				emotion e_thx;
				close;

				ssL_NotEnuf:
					mes "[Tempestra]";
					mes "Um.... where are those items exactly???";
					emotion e_hmm;
					close;
			ssM_1b:
				mes "[Tempestra]";
				mes "Come back anytime when you've changed your mind.";
				close;

		L_NoPot:
			mes "[Tempestra]";
			mes "Umm... excuse me but.... where is the potion??";
			emotion e_hmm;
			close;

	M_1:
		mes "[Tempestra]";
		mes "..... How RUDE!!";
		emotion e_gasp;
		close;
}

//=======================================================================================================//
//						Turtle Quest
//=======================================================================================================//
// Gotanblue --------------------------------------------------------------------------
alberta.gat,247,123,5	script	Gotanblue	709,{
	if(TURTLE) goto L_Turtle;
	mes "[Gotanblue]";
	mes "Ha ha! The sea seems endless!! We cannot begin to grasp its size merely by gazing at it from land....";
	next;
	mes "[Gotanblue]";
	mes "Do you know what I mean?.....";
	close;

L_Turtle:
	mes "[Gotanblue]";
	mes "Oh! Your eyes.... they tell me everything!! You must have been sent by that drunken old man!";
M_Menu:
	next;
	menu "-Tell me about Turtle Island.",-, "-How Can I get there?",M_2, "-End Conversation",M_End;

		mes "[Gotanblue]";
		mes "So you wanna know about Turtle Island?... You think it's a great place?... Do you like it that much?...";
		next;
		mes "[Gotanblue]";
		mes "Well let me tell you something....";
		next;
		mes "[Gotanblue]";
		mes "TURTLE ISLAND TOOK THE LIVES OF MY CLOSEST FRIENDS!!";
		emotion e_gasp;
		next;
		mes "[Gotanblue]";
		mes "Can you POSSIBLY understand??.........";
		next;
		mes "[Gotanblue]";
		mes "It all happened a few decades ago....";
		next;
		mes "[Gotanblue]";
		mes "^5555FFJornadan Niliria^000000 and our comrades set off on a journey to find out if the legends about the island were true.";
		next;
		mes "[Gotanblue]";
		mes "It was summer when I was approached to become a member of Jornadan's team.";
		mes "I was only 20 then, and it was a huge honor for me to be a part of such a well respected group of men.";
		next;
		mes "[Gotanblue]";
		mes "Jornadan Niliria was a great treasure hunter, I was the best seaman of the bunch, and the others were all the very best at what they did.";
		next;
		mes "[Gotanblue]";
		mes "We decided to start our great adventure here, in Alberta.  This was because of a clue we found that put the location of Turtle Island near Alberta.";
		next;
		mes "[Gotanblue]";
		mes "We were all very exited and full of hope! We left everything behind and set sail to seek Turtle Island!";
		mes "We sailed all day and all night.  We eventually ran adrift, and could do nothing but sit and wait as the days passed.....";
		next;
		mes "[Gotanblue]";
		mes "Then one day... without warning... we were surrounded by a tremendously thick blanket of fog!!";
		mes "It was impossible to see anything past the length of your own arm!";
		next;
		mes "[Gotanblue]";
		mes "We could not tell which way was East and which way was West.  But it didn't matter... for we were all exhausted at that point.";
		next;
		mes "[Gotanblue]";
		mes "Then what we feared most happened.  A huge rock formation pierced through the fog right in front of us!";
		mes "There was no way to avoid it and we crashed violently into it, severely damaging our ship!!";
		emotion e_gasp;
		next;
		mes "[Gotanblue]";
		mes "Amazingly, the ship held together and we were able to continue on.";
		next;
		mes "[Gotanblue]";
		mes "Then like a beam of energy descending down from the heavens, the first ray of sunlight we had seen in weeks pierced through the fog onto our battered ship.";
		next;
		mes "[Gotanblue]";
		mes "And like magic the fog lifted to reveal what we had been searching so long and hard for.... that legendary place.... TURTLE ISLAND!!!!";
		next;
		mes "[Gotanblue]";
		mes "We set up camp immediately and rested our weary bodies.  A few days later we began to extensively search the island.";
		mes "What we found was shocking! Apparently someone had found the island before us.  He left a very well kept journal of his expedition.";
		next;
		mes "[Gotanblue]";
		mes "According to his journal, the man had come by himself to find the island.  Unfortunately, we couldn't find him.";
		next;
		mes "[Gotanblue]";
		mes "Even though someone had beaten us to Turtle Island, we still felt that it was an accomplishment to have made it to the island.";
		mes "We continued to explore the island and find out as much about it as we could.";
		next;
		mes "[Gotanblue]";
		mes "A particular artifact caught our interest.  It was mentioned in that man's journal....";
		mes "Oh, now I remember his name... ^5555FF'Won'^000000... apparently a great sword master....";
		next;
		mes "[Gotanblue]";
		mes "Anyway, he wrote about a '^FF5555Jewel Fragment'^000000 of some kind.  He described it as 'the most beautiful thing in the world'.";
		next;
		mes "[Gotanblue]";
		mes "We became intent on finding that jewel no matter what.  Day after day we searched for it.  Months passed.";
		mes "But even with Won's journal records, we were not able to find the jewel fragment.  We had no choice but to give up.";
		next;
		mes "[Gotanblue]";
		mes "So we packed up our belongings and headed home.  Again we passed through the horrible dense fog.";
		mes "After a month of sailing our journey was near its end... or so we thought.";
		next;
		mes "[Gotanblue]";
		mes "We spotted land and I breathed a sigh of relief... unfortunately that feeling of relief turned into bewilderment as I realized that..... that....";
		next;
		mes "[Gotanblue]";
		mes "IT WAS TURTLE ISLAND!!! We had landed on the other side of the island! We had no idea how it happened but we immediately cast off once again.";
		emotion e_gasp;
		next;
		mes "[Gotanblue]";
		mes "And as if some foul curse and been placed on our group, we again found ourselves on the shores of Turtle Island.";
		mes "Time after time we attempted to flee the island only to find ourselves back on it.  A whole year passed and still, we were trapped!";
		next;
		mes "[Gotanblue]";
		mes "It was beyond reason.... We had tried every possible path.... Our spirits were broken, our hopes were crushed....";
		mes "And one by one, my comrades fell, no longer having the strength to find a way home....";
		next;
		mes "[Gotanblue]";
		mes "CURSED ISLAND!!!!!";
		emotion e_omg;
		next;
		mes "[Gotanblue]";
		mes "As you can see only I and Jornadan were able to make it out alive.  By pure luck, we made back to Alberta....";
		next;
		mes "[Gotanblue]";
		mes "(~sob~sob~sob)... I apologize. I'm still very emotional about it after all these years... Well, that's all I have to say about Turtle Island.";
		emotion e_sob;
		goto M_Menu;
	M_2:
		mes "[Gotanblue]";
		mes "What's this? After my terrifying story about Turtle Island, you still want to go there? You're not at all scared??";
		emotion e_what;
		next;
		mes "[Gotanblue]";
		mes "So be it... but you will need me as your guide and that will cost 10,000 zeny!";
		next;
		menu "Turtle Island -> 10000 zeny",-, "Cancel",sM_End;

			if(Zeny < 10000) goto sL_Zeny;
			mes "[Gotanblue]";
			mes "Alright!! You've made your choice! With my experience we will get to Turtle Island without any problems.";
			mes "I admire your fighting spirit.  Carry it with you always!";
			next;
			mes "^5555FF(You and Gotanblue climb on board his little steamboat)^000000";
			next;
			mes "[Gotanblue]";
			mes "We are now heading towards Turtle Island.  Let us go without fear!!";
			next;
			mes "^5555FF(~choo~choooo~)^000000";
			next;
			if(Zeny < 10000) goto sL_Zeny;
			set Zeny, Zeny - 10000;
			warp "tur_dun01.gat",154,39;
			close;
		sL_Zeny:
			mes "[Gotanblue]";
			mes "What's this? I said 10,000 zeny.  I will not guide you for less.  Good day!";
			emotion e_what;
			close;
		sM_End:
			mes "[Gotanblue]";
			mes "A very good choice!! Turtle Island is a DREADFULL and EVIL place!";
			mes "When I take people there, I feel as if I'm leading them to their DEATHS!";
			close;
	M_End:
		mes "[Gotanblue]";
		mes "To this day, Turtle Island is shrouded in mystery.  It is extremely hard to find, and almost impossible to escape from.";
		mes "If you do not want to suffer great despair, then leave the truth behind Turtle Island as it is.... unknown....";
		close; 
}

//Go back to Alberta
tur_dun01.gat,166,29,1	script	Gotanblue#2	709,{
	mes "[Gotanblue]";
	mes "Going back to Alberta?";
	next;
	menu "Yep.",-, "Cancel",M_End;

	mes "^5555FF(You and Gotanblue climb on board his little steamboat)^000000";
	next;
	warp "alberta.gat",244,123;
	close;

M_End:
	mes "[Gotanblue]";
	mes "A very good choice!!";
	close;
}

// Turtle Grandpa -------------------------------------------------------------------
alberta_in.gat,23,104,2	script	Turtle Grandpa	120,{
	mes "[Turtle Grandpa]";
	mes "~Buuurrrpp!!!~ Oops...";
	emotion e_swt;
	next;
	mes "[Turtle Grandpa]";
	mes "It's beyond me why people seem to think that Alberta is the center of world trade.";
	mes "I mean, this place doesn't even have a decent bar for crying out loud!!";
	emotion e_an;
	next;
	mes "[Turtle Grandpa]";
	mes "Why is it that I have to resort to drinking in a place like this??";
	emotion e_what;
	next;
	menu "-Tell me about Turtle Island.",-, "-How can I get there?",M_1, "-End conversation.",M_End;

		mes "[Turtle Grandpa]";
		mes "There is an enormous stash of treasure hidden on Turtle Island.";
		mes "There is also a special potion that can increase a person's lifespan on that island......";
		next;
		mes "[Turtle Grandpa]";
		mes "There are so many myths and legends about the island, that no one even knows for sure if Turtle Island exist.";
		next;
		mes "[Turtle Grandpa]";
		mes "I for one believe it does.... It HAS TO!!......";
		emotion e_gasp;
		next;
		mes "[Turtle Grandpa]";
		mes "If you are any sort of seaman, if you have a spirit for adventure, and if you have the heart to become a great treasure hunter....";
		mes "Then you may be worthy of the information I have to offer...";
		next;
		menu "-(~eyes twinkle~)",-, "-Heck Ya! Gimme that information.",sM_1;

			mes "[Turtle Grandpa]";
			mes "His name was ^5555FFJornadan Niliria^000000.  Jornadan and his ten comrades set off on a journey to find the legendary Turtle Island.";
			next;
			mes "[Turtle Grandpa]";
			mes "At first they had no idea where the island was.  They were ambitious and worked extremely hard to gather clues on the whereabouts of the island.";
			next;
			mes "[Turtle Grandpa]";
			mes "These men were very strong, especially Jornadan.  He was so strong in fact, that his simple kicks were as powerful as a level 10 bash!!!";
			next;
			mes "[Turtle Grandpa]";
			mes "He could catch an arrow in one hand while healing a comrade with the other, all during the middle of a battle!";
			next;
			mes "[Turtle Grandpa]";
			mes "Heh heh.  Well, it's just a rumor so take it for what it's worth.  As I was saying....";
			next;
			mes "[Turtle Grandpa]";
			mes "After searching tirelessly Jornadan and his crew eventually found the famed Turtle Island.";
			next;
			mes "[Turtle Grandpa]";
			mes "But for reasons unknown, the crew became stranded on the island forever!!";
			mes "Although I do not know why or how it happened, there IS one person that does.";
			next;
			mes "[Turtle Grandpa]";
			mes "Go the docks on the east end of town.  Look for a scholar named.... ^FF3333Jornadan^000000... ^FF3333Niliria^000000...";
			mes "Speak to him.  He should be able to tell you more..... ";
			next;
			mes "[Turtle Grandpa]";
			mes "Oh! One more thing... look for his '^5555FFjournal^000000'.  He usually has it close by.  It's definitely an interesting read.";
			if(TURTLE==0) set TURTLE, 1;
			close;
		sM_1:
			mes "[Turtle Grandpa]";
			mes "No way! I have no interest in speaking with someone with greed in his/her heart!";
			emotion e_gasp;
			next;
			mes "[Turtle Grandpa]";
			mes "Get OUT of my sight!!! GO HOME!";
			emotion e_an;
			next;
			mes "[Turtle Grandpa]";
			mes "What's this?? You're still here?..... GO! GO AWAY!!............";
			emotion e_go;
			close;
	M_1:
		mes "[Turtle Grandpa]";
		mes "It's is extremely hard to find, and even more difficult to reach.  The likelihood of returning home is slim at best....";
		next;
		mes "[Turtle Grandpa]";
		mes "Actually..... IT'S IMPOSSIBLE!!!!";
		emotion e_gasp;
		next;
		mes "[Turtle Grandpa]";
		mes "Yet you still want to go there??";
		emotion e_what;
		next;
		mes "[Turtle Grandpa]";
		mes "I want to warn you about the dangers of going there.... but.... I feel so dizzy..... wooah..... it must be the Vodka....";
		next;
		mes "[Turtle Grandpa]";
		mes "Any who, if you go the docks you'll find a fat, old, sailor.  His name is ^5555FFGotanblue^000000.";
		mes "Tell him I sent you and maybe he'll tell you how to get to Turtle Island.  Well, good luck.";
		close;
	M_End:
		mes "[Turtle Grandpa]";
		mes "Whooops......";
		next;
		mes "!!KA-PLOP!!(collapses on the floor)";
		next;
		mes "[Turtle Grandpa]";
		mes "He he he.... look at me.... I'm a fish... I'm drunk like a fish..... enough for today..... ~ZZZZZzzzz~";
		close;
}

// Letter of an explorer (on Turtle Grandpa's desk)------------------------------------------------------------------
alberta_in.gat,17,101,1	script	Letter of an explorer	111,{
	mes "~ The letter reads... ~";
	mes "- O/X/XOVX -";
	mes "If you find this letter, it means that our expedition to Turtle Island has failed.  Please inform the others...";
	next;
	mes "~ continued...~";
	mes "As of now, only half the number of our crew members are left.  Our food supply will only last for ten more days.  It is a grave situation we are facing....";
	next;
	mes "~ continued...~";
	mes "- V/O/XOVX -";
	mes "It seems my letters did not make it to the outside world, and have instead come back to me.... This damn island is CURSED!! Oh God.....";
	next;
	mes "~ continued...~";
	mes "GOD FORSAKEN ISLAND!! There is nothing left to eat..... help... me... please.... HELP ME!!";
	next;
	mes "~ continued...~";
	mes "- V/X/XOVX -";
	mes "^5555FF- This section is severely crumpled and tattered. -^000000";
	mes "^5555FF- You are unable to read it. -^000000";
	close;
}

// Jornadan Niliria ------------------------------------------------------------------------
alberta.gat,248,90,1	script	Jornadan Niliria	121,{
	mes "[Jornadan Niliria]";
	mes "Sometimes I think that the world around me is ever changing.";
	mes "When I view the land it seems different, when I look up at the sky it too seems different....";
	next;
	mes "[Jornadan Niliria]";
	mes "The way that Alberta and Turtle Island are different.  Hah hah hah....";
	next;
	menu "-About Turtle Island.",-, "-Um, did you get confused with Al De Baran?",M_1, "-End Conversation.",M_End;

		mes "[Jornadan Niliria]";
		mes "Ah yes..... Turtle Island.... Do you know why it's named, 'Turtle' Island? Would you like to know? Haha......";
		next;
		mes "[Jornadan Niliria]";
		mes "The reason behind the name is actually very easy to figure out and you might even feel a little foolish about not getting it in the first place.";
		next;
		mes "[Jornadan Niliria]";
		mes "It's called 'Turtle' Island, because of the fact that it is shaped like an actual turtle.  Haha.  That's all there is to it.";
		next;
		mes "[Jornadan Niliria]";
		mes "There is an unusually dense area of fog that surrounds the island.";
		mes "At first we tried to figure what causes it but with no luck.  We figured that it was just a natural phenomenon.";
		next;
		mes "[Jornadan Niliria]";
		mes "Then we found a cave along the coastline of the island.  Inside we were amazed to see a HUGE waterfall.";
		mes "It turns out that this waterfall is what creates that extremely thick area of fog around that island.";
		next;
		mes "[Jornadan Niliria]";
		mes "The reason is so simple and yet there are people who still try to find a deeper meaning behind it....";
		next;
		mes "[Jornadan Niliria]";
		mes "I believe that people continue to probe into the matter because they do not want to feel that their efforts have been in vain.";
		mes "Maybe they are afraid of the truth..... I for one was once afraid.... afraid of Turtle Island....";
		next;
		mes "[Jornadan Niliria]";
		mes "But now that I truly understand all of the myths about Turtle Island, I feel at ease and at peace with the island.";
		mes "There is still one lingering question about the island for me though..... it is the existence of the unknown ^FF5555'Jewel Fragment'^000000.";
		next;
		mes "[Jornadan Niliria]";
		mes "I am still not certain about what it really is.  In the mean time I will continue to pursue the matter until I discover the truth! Hahaha!!";
		close;
	M_1:
		mes "[Jornadan Niliria]";
		mes "Whoops ! Oh that's right !! Confused !.... Yipe !..... WOOOOO !!!";		//have NO idea what this means.....
		close;
	M_End:
		mes "[Jornadan Niliria]";
		mes "When you're searching for the truth, make sure to keep trying.  Someday you will find the answers you seek...";
		next;
		mes "[Jornadan Niliria]";
		mes "Hmmm.... by the way.... I feel hungry.  Why doesn't Alberta have a store or restaurant for some good Dim Sum??";
		close;
}

// Jornadan's Voyage Log -------------------------------------------------
alberta.gat,247,93,1	script	A Voyage Log	111,{
	if(TURTLE == 1) goto L_Treasure;
	mes "[A Voyage Log]";
	mes "= 03:20 am =";
	mes "The moon was dark and I couldn't even see 100m in front of me.  I had a bad feeling about the situation..... I was not the only one...";
	next;
	mes "[A Voyage Log]";
	mes "I could tell by the looks on my comrade's faces, that they too were worried.  No one could sleep that night.  I hope we will see the sunrise soon....";
	next;
	mes "[A Voyage Log]";
	mes "= 04:10 =";
	mes "5 minutes ago one of our comrades, Cooker, died.  While he walking on deck, the flagpole suddenly broke and fell on his head....";
	next;
	mes "[A Voyage Log]";
	mes "He died at approximately 04:07.  The flagpole had been damaged when our ship hit a reef.";
	mes "The ship sustained serious damage along the left side of the deck.  I called on the chief to repair it.";
	next;
	mes "[A Voyage Log]";
	mes "= 04:45 =";
	mes "While two of our workers were fixing the bottom of the deck, monsters attacked them without warning.";
	mes "Apparently they had gotten in through some openings in the deck.";
	next;
	mes "[A Voyage Log]";
	mes "Two more men had been lost.  Fortunately the ship has yet to sink and seems to be holding up.  Still, we must find land soon.";
	next;
	mes "[A Voyage Log]";
	mes "During the collision with the reef we lost about 30% of our supplies.  In particular we lost food... a great deal of food....";
	next;
	mes "[A Voyage Log]";
	mes "= 05:23 =";
	mes "We've been noticing an increase in the amount of reefs and they are getting larger as well.";
	mes "I wonder when we will find land.... I wonder if we can....";
	next;
	mes "[A Voyage Log]";
	mes "- Written by -";
	mes "- captain Jornadan Niliria -";
	next;
	mes "^5555FF- Closed the voyage log -^000000";
	close;

L_Treasure:
	mes "^5555FF- The paper is torn -";
	mes "- Seaweed and mold have -";
	mes "- mixed with the paper -";
	mes "- It looks to be in very poor";
	mes "condition. -^000000";
	next;
	mes "^5555FF- Between some pages -";
	mes "- Is a Banana leaf -";
	mes "- this is written. -^000000";
	next;
	mes "[A Voyage Log]";
	mes "= O/X date =";
	mes "Just after we arrived to Turtle Island, we searched for some food to eat.  I am so skinny now...";
	next;
	mes "[A Voyage Log]";
	mes "When I looked at myself in the mirror, it was horrible.  I was disturbed by what I saw...";
	next;
	mes "[A Voyage Log]";
	mes "= X/X date =";
	mes "We found some kind of fruit! It has a yellow color and a long shape.  It looks just like a banana!";
	next;
	mes "[A Voyage Log]";
	mes "= XO/X date =";
	mes "Although very similar, the fruit we found was not a banana.  We believe it is a relative of the banana.";
	mes "It smells and tastes exactly like a banana.";
	next;
	mes "[A Voyage Log]";
	mes "We were starving so we just referred to the fruit as bananas and gathered it for food.";
	mes "Although there were a limited amount of trees, there was enough for our survival.";
	next;
	mes "[A Voyage Log]";
	mes "It has become the answer to our lack of food and has become precious to us.";
	mes "~ WE LOVE YOU BANANA!! ~";
	next;
	mes "[A Voyage Log]";
	mes "= O/O date =";
	mes "In the middle of the night, one of our comrades reported that he felt sick from something he ate.";
	next;
	mes "[A Voyage Log]";
	mes "= OO/O date =";
	mes "Another comrade fell ill.  He had the strongest digestive system among us.";
	mes "He went by the name, 'Berot Berot', and he played a vital role in our group.";
	next;
	mes "[A Voyage Log]";
	mes "The fact that he got sick from something he ate, made it very clear that there was something poisoning us.";
	next;
	mes "[A Voyage Log]";
	mes "= XO/O date =";
	mes "A third person became sick today while we were out exploring.  The first person to become ill has passed away.... We are all very worried.";
	next;
	mes "[A Voyage Log]";
	mes "We tried very hard to find the cause of the illness.  Then by observing the animals one day, we found it.";
	mes "It was the very thing we thought to be our salvation and yet not one animal on the island would even touch it.....";
	next;
	mes "[A Voyage Log]";
	mes "What was killing us was..... our beloved BANANA!!";
	next;
	mes "[A Voyage Log]";
	mes "We decided to get rid of all of the bananas.  But for some reason they didn't seem to be decomposing.";
	mes "Even when the skin was peeled off, the fruits remained the same.";
	next;
	mes "[A Voyage Log]";
	mes "I think that the poison or some other agent within the fruit is allowing it to survive.";
	mes "We may be able to use it for medicinal purposes later, but for now it is of no use to us.";
	mes "Until we get back to Alberta, we have to decided to bury what is left of the fruit.";
	next;
	mes "[A Voyage Log]";
	mes "This is the location where it's buried in case we forget:";
	mes "^FF8888- tur_dun01 -";
	mes "- X: 160, Y: 81 -^000000";
	next;
	mes "^5555FF- There is a thin Key -";
	mes "- with a skull mark on it -";
	mes "- You've gained -";
	mes "- a 'Skull Key' -^000000";
	set TURTLE, 2;
	close;
}

// Burried treasure --------------------------------------------------------------------
tur_dun01.gat,160,80,1	script	Skull Stone	111,{
	if(TURTLE == 2) goto L_OpenBox;
	mes "^5555FF(It's a frightening stone tomb with horrible skull on it.)^000000";
	close;

L_OpenBox:
	mes "^5555FF(Under the stone is a tiny key hole with a skull mark.  You used the 'Skull Key' to open the box.)^000000";
	next;
	mes "^5555FF(~click!~click!~)^000000";
	next;
	mes "^5555FF(Suddenly the top of the stone opens with many things coming out!)^000000";
	set TURTLE, 3;
	next;
	mes "^5555FF(You got 5 Tropical Bananas and 5 Banana Juices.)^000000";
	getitem 634, 5;
	getitem 532, 5;
	close;
}